From 31543699451d57fe9c49222dea50cd734edfaf76 Mon Sep 17 00:00:00 2001
From: David Roman <davidroman96@gmail.com>
Date: Sun, 10 Dec 2017 18:15:28 +0100
Subject: [PATCH] www-misc/buku: new package.

Buku is a popular command-line bookmark manager.

Closes: https://bugs.gentoo.org/640612
Closes: https://github.com/gentoo/gentoo/pull/6510
---
 www-misc/buku/Manifest        |  1 +
 www-misc/buku/buku-3.5.ebuild | 48 +++++++++++++++++++++++++++++++++++
 www-misc/buku/metadata.xml    | 15 +++++++++++
 3 files changed, 64 insertions(+)
 create mode 100644 www-misc/buku/Manifest
 create mode 100644 www-misc/buku/buku-3.5.ebuild
 create mode 100644 www-misc/buku/metadata.xml

diff --git a/www-misc/buku/Manifest b/www-misc/buku/Manifest
new file mode 100644
index 000000000000..1b2763a2fe92
--- /dev/null
+++ b/www-misc/buku/Manifest
@@ -0,0 +1 @@
+DIST buku-3.5.tar.gz 93634 BLAKE2B 55c4b50b3bf8121c116554613768cd836080b363d702469eb2f76349c26d8d6246f73746248123030c5657006e09a9f72242354ce3af20d93b845f1870929bbc SHA512 b9f70665c83033ca030302e805ee051a524b2f0decae6c99ad54749b4a4bc91ae8261976018741361489525f359ea71c01ddb3e2d827ab9a052fb0acc98be8ed
diff --git a/www-misc/buku/buku-3.5.ebuild b/www-misc/buku/buku-3.5.ebuild
new file mode 100644
index 000000000000..ec2ba66f777d
--- /dev/null
+++ b/www-misc/buku/buku-3.5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Powerful command-line bookmark manager"
+HOMEPAGE="https://github.com/jarun/Buku"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.13.1[${PYTHON_USEDEP}]
+"
+
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/flake8[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/py[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-catchlog[${PYTHON_USEDEP}]
+	)
+"
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr/share/zsh/site-functions
+	doins auto-completion/zsh/_*
+
+	newbashcomp auto-completion/bash/buku-completion.bash "${PN}"
+
+	doman buku.1
+}
+
+python_test() {
+	py.test -v tests/test_* || die
+}
diff --git a/www-misc/buku/metadata.xml b/www-misc/buku/metadata.xml
new file mode 100644
index 000000000000..e3171793d0f6
--- /dev/null
+++ b/www-misc/buku/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>davidroman96@gmail.com</email>
+		<name>David Roman</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">jarun/Buku</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
2.26.2