From 304b651dbab69be08d2a02c1b7e3116798eb954b Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 24 Nov 2019 14:21:52 +0100
Subject: [PATCH] media-libs/libheif: 1.6.0 version bump

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-libs/libheif/Manifest             |  1 +
 media-libs/libheif/libheif-1.6.0.ebuild | 67 +++++++++++++++++++++++++
 media-libs/libheif/libheif-9999.ebuild  |  7 +--
 3 files changed, 72 insertions(+), 3 deletions(-)
 create mode 100644 media-libs/libheif/libheif-1.6.0.ebuild

diff --git a/media-libs/libheif/Manifest b/media-libs/libheif/Manifest
index 3ce898843671..85e430f2263b 100644
--- a/media-libs/libheif/Manifest
+++ b/media-libs/libheif/Manifest
@@ -1 +1,2 @@
 DIST libheif-1.5.1.tar.gz 1510087 BLAKE2B 1dd5e913c8913c6b62b770653585f8ccf7cda14c4dd79ff2073bf085da4d730accaef8d0f8008ac941238a7e3e131add1a218e0c78a886847b3bcf253d66c9b6 SHA512 05e32ebff08d5f0e82e9b1107253c27882ae1694150033fe7b3ca07db8c64567f09002081276e92a3b490a63022a1522d577b094a7f489742139758d17f484b8
+DIST libheif-1.6.0.tar.gz 1512262 BLAKE2B db27c65130250d018d8bce9b793d281b9bc3928ef378f8d3180bd0236e7f92810b08da9aaea227733d533cd871712319da1263a9020c5e2dbcfda20ab13f6978 SHA512 25e3f08663224321a5d7646543787f026c0fc344e1b26c90b7b48247a7c036836112d104f3559b1c3c96c0252b2ce5efaaed456ccd0ae648f70e4055d81f2f00
diff --git a/media-libs/libheif/libheif-1.6.0.ebuild b/media-libs/libheif/libheif-1.6.0.ebuild
new file mode 100644
index 000000000000..cbf2d5eaaaad
--- /dev/null
+++ b/media-libs/libheif/libheif-1.6.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit autotools xdg-utils multilib-minimal
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/strukturag/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/strukturag/${PN}/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+DESCRIPTION="ISO/IEC 23008-12:2017 HEIF file format decoder and encoder"
+HOMEPAGE="https://github.com/strukturag/libheif"
+
+LICENSE="GPL-3"
+SLOT="0/1.6"
+IUSE="static-libs test +threads"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-lang/go )"
+DEPEND="
+	media-libs/libde265:=[${MULTILIB_USEDEP}]
+	media-libs/libpng:0=[${MULTILIB_USEDEP}]
+	media-libs/x265:=[${MULTILIB_USEDEP}]
+	sys-libs/zlib:=[${MULTILIB_USEDEP}]
+	virtual/jpeg:0=[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	sed -i -e 's:-Werror::' configure.ac || die
+
+	eautoreconf
+
+	# prevent "stat heif-test.go: no such file or directory"
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable threads multithreading)
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name '*.la' -delete || die
+	if ! use static-libs ; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}
diff --git a/media-libs/libheif/libheif-9999.ebuild b/media-libs/libheif/libheif-9999.ebuild
index 0d11fc08e5b2..cbf2d5eaaaad 100644
--- a/media-libs/libheif/libheif-9999.ebuild
+++ b/media-libs/libheif/libheif-9999.ebuild
@@ -17,9 +17,11 @@ DESCRIPTION="ISO/IEC 23008-12:2017 HEIF file format decoder and encoder"
 HOMEPAGE="https://github.com/strukturag/libheif"
 
 LICENSE="GPL-3"
-SLOT="0/1.5"
+SLOT="0/1.6"
 IUSE="static-libs test +threads"
 
+RESTRICT="!test? ( test )"
+
 BDEPEND="test? ( dev-lang/go )"
 DEPEND="
 	media-libs/libde265:=[${MULTILIB_USEDEP}]
@@ -33,8 +35,7 @@ RDEPEND="${DEPEND}"
 src_prepare() {
 	default
 
-	sed -i -e 's:-Werror::' \
-		configure.ac || die
+	sed -i -e 's:-Werror::' configure.ac || die
 
 	eautoreconf
 
-- 
2.26.2