From 2f5f3597c24a5372120a1f69c4ce4e368d35f426 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sat, 29 Aug 2015 17:29:09 -0700
Subject: [PATCH] dev-libs/wayland: Add git ebuild.

---
 dev-libs/wayland/wayland-9999.ebuild | 63 ++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 dev-libs/wayland/wayland-9999.ebuild

diff --git a/dev-libs/wayland/wayland-9999.ebuild b/dev-libs/wayland/wayland-9999.ebuild
new file mode 100644
index 000000000000..ae7ec6702a98
--- /dev/null
+++ b/dev-libs/wayland/wayland-9999.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="git://anongit.freedesktop.org/git/${PN}/${PN}"
+	GIT_ECLASS="git-r3"
+	EXPERIMENTAL="true"
+	AUTOTOOLS_AUTORECONF=1
+fi
+
+inherit autotools-multilib toolchain-funcs $GIT_ECLASS
+
+DESCRIPTION="Wayland protocol libraries"
+HOMEPAGE="http://wayland.freedesktop.org/"
+
+if [[ $PV = 9999* ]]; then
+	SRC_URI="${SRC_PATCHES}"
+	KEYWORDS=""
+else
+	SRC_URI="http://wayland.freedesktop.org/releases/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc static-libs"
+
+RDEPEND=">=dev-libs/expat-2.1.0-r3:=[${MULTILIB_USEDEP}]
+	>=virtual/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? (
+		>=app-doc/doxygen-1.6[dot]
+		app-text/xmlto
+		>=media-gfx/graphviz-2.26.0
+		sys-apps/grep[pcre]
+	)
+	virtual/pkgconfig"
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable doc documentation)
+	)
+	if tc-is-cross-compiler ; then
+		myeconfargs+=( --disable-scanner )
+	fi
+	if ! multilib_is_native_abi; then
+		myeconfargs+=( --disable-documentation )
+	fi
+
+	autotools-multilib_src_configure
+}
+
+src_test() {
+	export XDG_RUNTIME_DIR="${T}/runtime-dir"
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	autotools-multilib_src_test
+}
-- 
2.26.2