From 2e42572fb3fa4357c2a2dfea0dea2da4888a535e Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 24 Nov 2019 17:03:34 +0100
Subject: [PATCH] dev-python/translate-toolkit: 2.4.0 version bump, python3_8

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-python/translate-toolkit/Manifest         |  1 +
 .../translate-toolkit-2.4.0.ebuild            | 80 +++++++++++++++++++
 2 files changed, 81 insertions(+)
 create mode 100644 dev-python/translate-toolkit/translate-toolkit-2.4.0.ebuild

diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index ed22261aea19..dd2c7d0892e1 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1,2 +1,3 @@
 DIST translate-toolkit-2.0.0.tar.gz 1106464 BLAKE2B 419caa924b36abd45cd285a28594dad7d1d49dd149961a686382f848e85d6bb15c4cbf52b28881efa7643a9470a51d2c00c57ce52c153a113296344054e31038 SHA512 a349f64438683bb00a7a7ba0537b7c9a268e6222d2df67991eb5d47b05a446a6049bf42918edc97ba8b08a89a42850eb37f6b4b917ccf5c44494885a853ffe1f
 DIST translate-toolkit-2.3.1.tar.gz 7668931 BLAKE2B b8426c06cfd01d6afcc88b629cf464e6fa91a49a6a3399cdc693395f67677bc8eeb4bb1ce0b5a1653ce0e6cafabf76cc102ab462d0482cbf311e5369f65df678 SHA512 8928d1d681dfb4cd9100ae6128f6e1d7e85ff518e6f529c37d01e34679470e9d964c08dfbb902edc23403ff6f6912d0a4236fe0cb21819d00d9ba46c3009ace3
+DIST translate-toolkit-2.4.0.tar.gz 7646438 BLAKE2B 5d956ce05b57aa3ec2c7896a36f199cab5a590d4d6a4ad84263d7b757e35d5e42a40cac38ea3da1c8a11c64b1cacff5a5742b79ad5a87436842a35547d89e611 SHA512 715d9e974c451a5c3d92471287f4da8e8ba663efda849398f77a3c3d6f16e0c9a8e685261ec07c02ce9bd13f3766f0b2b1ad441b92116bb3913036ffbd415658
diff --git a/dev-python/translate-toolkit/translate-toolkit-2.4.0.ebuild b/dev-python/translate-toolkit/translate-toolkit-2.4.0.ebuild
new file mode 100644
index 000000000000..b45fd6a1b2e7
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-2.4.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/translate/translate/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc +html +ical +ini +subtitles +yaml"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	doc? ( || ( $(python_gen_useflags python3_6 python3_7) ) )
+	subtitles? ( || ( $(python_gen_useflags python3_6 python3_7) ) )"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( $(python_gen_cond_dep 'dev-python/sphinx[${PYTHON_USEDEP}]' python3_6 python3_7) )
+"
+DEPEND="
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.5[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-18.5.26[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( dev-python/iniparse[${PYTHON_USEDEP}] )
+	subtitles? ( $(python_gen_cond_dep 'media-video/gaupol[${PYTHON_USEDEP}]' python3_6 python3_7) )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	# Prevent unwanted d'loading in doc build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" \
+		-e "/html_theme/ s/sphinx-bootstrap/classic/" \
+		-i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( "${S}"/docs/_build/html/. )
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	rm -Rf docs || die
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}
-- 
2.26.2