From 2acce2cca3427b50d26a717f81ed3313255bb7a4 Mon Sep 17 00:00:00 2001
From: =?utf8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 9 Nov 2019 14:13:36 +0100
Subject: [PATCH] net-misc/tiers: Bump to EAPI 7
MIME-Version: 1.0
Content-Type: text/plain; charset=utf8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/697226
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 net-misc/tiers/tiers-1.1.ebuild | 43 ++++++++++++++++++---------------
 1 file changed, 23 insertions(+), 20 deletions(-)

diff --git a/net-misc/tiers/tiers-1.1.ebuild b/net-misc/tiers/tiers-1.1.ebuild
index c8d77c98bb19..5d489c5a5959 100644
--- a/net-misc/tiers/tiers-1.1.ebuild
+++ b/net-misc/tiers/tiers-1.1.ebuild
@@ -1,42 +1,45 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
-
-inherit eutils
+EAPI=7
 
 MY_P="${PN}${PV}"
 DESCRIPTION="Random network topography generator"
 HOMEPAGE="http://www.isi.edu/nsnam/ns/ns-topogen.html#tiers"
 SRC_URI="http://www.isi.edu/nsnam/dist/topogen/${MY_P}.tar.gz
-		 http://www.isi.edu/nsnam/dist/topogen/tiers2ns-lan.awk"
+	http://www.isi.edu/nsnam/dist/topogen/tiers2ns-lan.awk"
 
 LICENSE="mapm"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc x86"
 IUSE=""
 
-DEPEND="sys-devel/gcc"
-RDEPEND="virtual/awk
-	sci-visualization/gnuplot"
-
-S=${WORKDIR}/${PN}${PV}
+RDEPEND="sci-visualization/gnuplot
+	virtual/awk"
 
-src_unpack() {
-	unpack ${MY_P}.tar.gz
-	cd "${S}"
+S=${WORKDIR}/${MY_P}
 
-	epatch "${FILESDIR}"/${MY_P}-gccfixes.patch
-	epatch "${FILESDIR}"/${P}-gcc43.patch
-	sed -e '1a\#!/bin/sh' -e '1d' -e "s|-f |-f /usr/share/${PN}/|g" -i "${S}"/bin/strip4gnuplot3.5
+src_prepare() {
+	default
+	eapply "${FILESDIR}"/${MY_P}-gccfixes.patch
+	eapply "${FILESDIR}"/${P}-gcc43.patch
+	sed -e '1a\#!/bin/sh' \
+		-e '1d' \
+		-e "s|-f |-f /usr/share/${PN}/|g" \
+		-i "${S}"/bin/strip4gnuplot3.5 || die
 }
 
 src_compile() {
-	cd "${S}"/src
-	emake CFLAGS="${CFLAGS}" CONFIGFILE="/etc/tiers-gnuplot.conf" EXEC="../bin/tiers-gnuplot" || die
+	emake -C src \
+		CFLAGS="${CFLAGS}" \
+		CONFIGFILE="/etc/tiers-gnuplot.conf" \
+		EXEC="../bin/tiers-gnuplot"
 	# cleanup for a sec
-	rm *.o
-	emake CFLAGS="${CFLAGS}" CONFIGFILE="/etc/tiers.conf" EXEC="../bin/tiers" || die
+	rm src/*.o || die
+	emake -C src \
+		CFLAGS="${CFLAGS}" \
+		CONFIGFILE="/etc/tiers.conf" \
+		EXEC="../bin/tiers"
 }
 
 src_install() {
-- 
2.26.2