From 284f17e0d11b2dab843a7afd9b5f5259f46a2dbd Mon Sep 17 00:00:00 2001
From: Sebastian Pipping <sping@gentoo.org>
Date: Fri, 27 Dec 2019 17:44:49 +0100
Subject: [PATCH] dev-python/mako: Python 3.8

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.83, Repoman-2.3.20
---
 dev-python/mako/mako-1.0.7-r1.ebuild | 50 ++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/mako/mako-1.0.7-r1.ebuild

diff --git a/dev-python/mako/mako-1.0.7-r1.ebuild b/dev-python/mako/mako-1.0.7-r1.ebuild
new file mode 100644
index 000000000000..90a0a1f41662
--- /dev/null
+++ b/dev-python/mako/mako-1.0.7-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7,8}} )
+
+inherit distutils-r1 eutils
+
+MY_PN="Mako"
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="http://www.makotemplates.org/ https://pypi.org/project/Mako/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' pypy python2_7)
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_test() {
+	py.test -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	rm -r doc/build || die
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Optional dependencies:"
+	optfeature "caching support" dev-python/beaker
+}
-- 
2.26.2