From 22f38be9484db2e448597a9fc54d691b9e1c031a Mon Sep 17 00:00:00 2001
From: Alexis Ballier <aballier@gentoo.org>
Date: Sat, 26 Sep 2015 11:32:38 +0200
Subject: [PATCH] dev-util/rosdep: Bump to 0.11.4.

Package-Manager: portage-2.2.22
---
 dev-util/rosdep/Manifest             |  1 +
 dev-util/rosdep/rosdep-0.11.4.ebuild | 61 ++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 dev-util/rosdep/rosdep-0.11.4.ebuild

diff --git a/dev-util/rosdep/Manifest b/dev-util/rosdep/Manifest
index 949807d45d64..3b5b02d03632 100644
--- a/dev-util/rosdep/Manifest
+++ b/dev-util/rosdep/Manifest
@@ -1 +1,2 @@
 DIST rosdep-0.11.2.tar.gz 106456 SHA256 89da05bdc082005815a9679dc34509a16647374d746a9e636c4238dd8f7aed9e SHA512 55057bb478dce1a7be3025d52fa6fb616b2de95017981ead934d7965282fa6ceb81780b7825d914531f87af492f3b5ce91ecf2607e6bddb65e13744e8a8d6743 WHIRLPOOL 37407d99d58f62c00a54b94a5820cab599c7700be355132e5d7b9d277faa220f89d68c9950cd386e984c64a1f0c493d53db15b31082f485d4786aff232f73d34
+DIST rosdep-0.11.4.tar.gz 108842 SHA256 ded28bbf4821564feb8b62174f4ecac0031335c8357230e618a224b9ae1e8081 SHA512 0bffe2731e1039da63231bd57a98aa132a22fccfa6a8c3ed1553d51b0cf217d35eaaed524607f76132bd75332aae79187eb69d57ba1df8134159ede0a427953c WHIRLPOOL 4293a4d50d95882dd441e9d94eefc1c42ccb4195ba7faf1acb5081d7f7cae1ffde11842919ee45d7110e04f3a63b1ad4699fc9c768788aa1fe4afe35030c7192
diff --git a/dev-util/rosdep/rosdep-0.11.4.ebuild b/dev-util/rosdep/rosdep-0.11.4.ebuild
new file mode 100644
index 000000000000..7e6194f79a44
--- /dev/null
+++ b/dev-util/rosdep/rosdep-0.11.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/ros-infrastructure/rosdep"
+fi
+
+inherit ${SCM} distutils-r1
+
+DESCRIPTION="Command-line tool for installing ROS system dependencies"
+HOMEPAGE="http://wiki.ros.org/rosdep"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="http://download.ros.org/downloads/${PN}/${P}.tar.gz
+		http://github.com/ros-infrastructure/rosdep/archive/${PV}.tar.gz -> ${P}.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="test"
+
+RDEPEND="
+	dev-python/catkin_pkg[${PYTHON_USEDEP}]
+	dev-python/rospkg[${PYTHON_USEDEP}]
+	dev-python/rosdistro[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	nosetests --with-coverage --cover-package=rosdep2 --with-xunit test || die
+}
+
+pkg_postrm() {
+	if [ "${ROOT:-/}" = "/" ] ; then
+		einfo "Removing rosdep default sources list."
+		rm -f "${EPREFIX}/etc/ros/rosdep/sources.list.d/20-default.list"
+	fi
+}
+
+pkg_postinst() {
+	if [ "${ROOT:-/}" = "/" -a ! -f "${EPREFIX}/etc/ros/rosdep/sources.list.d/20-default.list" ] ; then
+		einfo "Initializing rosdep"
+		rosdep init
+	fi
+}
-- 
2.26.2