From 1305bbf63921baf14821bf7d71e06f08cce5f4b0 Mon Sep 17 00:00:00 2001
From: Virgil Dupras <vdupras@gentoo.org>
Date: Sat, 4 May 2019 16:30:41 -0400
Subject: [PATCH] dev-python/nbformat: drop py2

Bug: https://bugs.gentoo.org/685040
Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11
---
 dev-python/nbformat/nbformat-4.4.0-r1.ebuild | 57 ++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-python/nbformat/nbformat-4.4.0-r1.ebuild

diff --git a/dev-python/nbformat/nbformat-4.4.0-r1.ebuild b/dev-python/nbformat/nbformat-4.4.0-r1.ebuild
new file mode 100644
index 000000000000..854ea496fff1
--- /dev/null
+++ b/dev-python/nbformat/nbformat-4.4.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE='sqlite'
+
+inherit distutils-r1
+
+DESCRIPTION="Reference implementation of the Jupyter Notebook format"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/jsonschema-2.4.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.1[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/testpath[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	pytest -vv nbformat || die
+}
-- 
2.26.2