From 11217953768085ed292d43ad94f392e3ed30a0f7 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Wed, 9 Sep 2015 22:50:04 -0500
Subject: [PATCH] dev-python/python-neutronclient: bup

Package-Manager: portage-2.2.20.1
---
 dev-python/python-neutronclient/Manifest      |  1 +
 .../python-neutronclient-3.0.0.ebuild         | 92 +++++++++++++++++++
 2 files changed, 93 insertions(+)
 create mode 100644 dev-python/python-neutronclient/python-neutronclient-3.0.0.ebuild

diff --git a/dev-python/python-neutronclient/Manifest b/dev-python/python-neutronclient/Manifest
index 4f7e9f47da3c..e2c61c1ff71c 100644
--- a/dev-python/python-neutronclient/Manifest
+++ b/dev-python/python-neutronclient/Manifest
@@ -1,3 +1,4 @@
 DIST python-neutronclient-2.3.6.tar.gz 123143 SHA256 f2ae938654497e12218ca3105872a1d55c5ce06e19ed0baa8471ee024e494b1f SHA512 0d894ca7cbafe3c4f12a45e27953abdeedfeff009d96bc6852465089f64ee57f065d87067e79665a401e574100115eec8ae7bb7a220005955be4535c7a44bcb7 WHIRLPOOL d2f3aeda0894bb2f262b7761af6f64ecb80a3c15ef68fd4a6eb257446bf647e96eee5d51f692071ac776ee8c3f26ecb7314d825826070e2ddfbfcd84257e466d
 DIST python-neutronclient-2.4.0.tar.gz 137923 SHA256 4c5c3a79216c682926f75ffd8db5f4338525a643ea02de37df7bf82a1e486b28 SHA512 ce3407ec101ca0fe04da5fbb3d68e3e331824190ed6e93308e56a471b9bf1b0d873f6e7b733d205bccaba6567d87a0a829e442efb6a3b0d96ecee5a1abb5a071 WHIRLPOOL 28b798ed7605264ec6d1e69f4a98ba7eb7e825594dc0ca9d5941d5293810c4f7cd32c680d09be44077ee269f8bd0c8644543c477223d5b55f078f81a0993460f
 DIST python-neutronclient-2.6.0.tar.gz 141675 SHA256 ce72506c0720825edcb0e93b643340e044f1de9235d398fe1c45d851971020df SHA512 a14503ec5374f0edd647a4da5e75f5d6820388b73792a9c944537815e980e87890fea227b2d21e34207958350f6e08a002e6f09af5567e1b4d709e698ea040cb WHIRLPOOL 7d3e6b0baded7de81f2c010376e8b528a73715382a230ffc6790eaae58b54e9cb5765002d2a508953b22a498d5a60947decd0d2884254cb2cc12f7ae1550596f
+DIST python-neutronclient-3.0.0.tar.gz 147616 SHA256 f6dc2e514e99df4f7eaf9f983a19344a5f38adf323d71f2908c872f8eba88e2f SHA512 f985c054f614d8ec2102d5323e7320c578dd11685f34d5e3f791c0ea3efea3780731da0f777a1544250029cd6dda8484af623c1f4537b45e49386e1ae1e9820b WHIRLPOOL f3323f28c36461b2b64897bd69d9453cf0f91c6497126e3e0d539652711f653e20ca340dfcce429f5342cb9a9397ccd42783a79d1c4baabf108aed569d50b521
diff --git a/dev-python/python-neutronclient/python-neutronclient-3.0.0.ebuild b/dev-python/python-neutronclient/python-neutronclient-3.0.0.ebuild
new file mode 100644
index 000000000000..2b3731f01470
--- /dev/null
+++ b/dev-python/python-neutronclient/python-neutronclient-3.0.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="https://launchpad.net/neutron"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+REQUIRED_USE="test? ( doc )"
+
+CDEPEND="
+	>=dev-python/pbr-1.6[${PYTHON_USEDEP}]
+	<dev-python/pbr-2.0[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/cliff-tablib-1.0[${PYTHON_USEDEP}]
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/mox3-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/tempest-lib-0.6.1[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/cliff-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.12[${PYTHON_USEDEP}]
+	!~dev-python/netaddr-0.7.16[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.2[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# built in... 
+	sed -i '/^argparse/d' requirements.txt || die
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && "${PYTHON}" setup.py build_sphinx
+}
+
+python_test() {
+	testr init
+	testr run || die "tests failed under python2.7"
+	flake8 neutronclient/tests || die "run by flake8 over tests folder yielded error"
+}
+
+python_install() {
+	distutils-r1_python_install
+	#stupid stupid
+	local SITEDIR="${D%/}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.egg-info )
+	#[[ -f ${egg[0]} ]] || die "python_quantumclient*.egg-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}
-- 
2.26.2