From 027f3ac3b050bc9a869b1588059f33ed217a3254 Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Fri, 9 Oct 2015 01:02:21 +1100
Subject: [PATCH] app-crypt/qca: version bump

Package-Manager: portage-2.2.20.1
---
 app-crypt/qca/Manifest         |   1 +
 app-crypt/qca/qca-2.1.1.ebuild | 122 +++++++++++++++++++++++++++++++++
 2 files changed, 123 insertions(+)
 create mode 100644 app-crypt/qca/qca-2.1.1.ebuild

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
index 627c06d184ca..e2549c9728e4 100644
--- a/app-crypt/qca/Manifest
+++ b/app-crypt/qca/Manifest
@@ -1,2 +1,3 @@
 DIST qca-2.0.3.tar.bz2 4530731 SHA256 8da20c89f390954fdcfcd3c4deef379213ddb5ae9d6b5e0c917d23f5e474895f SHA512 c1120ffb373e294fbcc76e21dc2f503ebd3398b26d0ffa7ab7ee3a3e1a4228159358b59c2673ac4a1c2363771e61da54a5080b201c65d586ceda2e3b2facc1bb WHIRLPOOL 2efba46098490ab5a75dcdf95eeb7d81a5509a962403a44602caa126927ebe9e69cb043586dbaebf0b111b79e614b607ae851242d12af9fa17d2dd191e559b0e
+DIST qca-2.1.1.tar.xz 688460 SHA256 95de3e7910b5f9ec7084169989c9d98bfb527e6a4865fe17269c3b24308be983 SHA512 f077b5a4cc6539e0880f4d0a615bebcf851f634e99c6c355522598204f625e5195e0cbc8a1976593669018e57eff95796c8fef69b1301b42cb18736bc8aa1abf WHIRLPOOL 454751a76f5e59aa09d6cc979bc26a490b23a2e5308f663400f45f38a95e6ad7a34428cffb1a2a82ec6958aa0b4418e0054503a58b43e0c172201cbaa7c669f8
 DIST qca-qt5-2.1.0.3.tar.xz 685652 SHA256 ab0170696a8ff87588d38a72d36d0b4b42db9080c991d1a40ceb3f8311d289f9 SHA512 2f50c92d3ff927c83353b65ae56ff49a5c1ea439fcef94cea0092b718f04abcc18f455abd91337ac786fddedae980ff55c9d090b5743a96890174dc7eee4f3f1 WHIRLPOOL 9db2770b031dbf5c9c117d4150e0b395c94d8a0af1bda9fac5e1ee862a8a40f1c03fb0c4901e3aaba0b12e8c0b4e71cb55a872bbc54eea8331aff3fbe1fd853c
diff --git a/app-crypt/qca/qca-2.1.1.ebuild b/app-crypt/qca/qca-2.1.1.ebuild
new file mode 100644
index 000000000000..a4f34f16f5eb
--- /dev/null
+++ b/app-crypt/qca/qca-2.1.1.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils multibuild qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="http://delta.affinix.com/qca/"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+
+IUSE="botan debug doc examples gcrypt gpg libressl logger nss +openssl pkcs11 +qt4 qt5 sasl softstore test"
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	!app-crypt/qca-cyrus-sasl
+	!app-crypt/qca-gnupg
+	!app-crypt/qca-logger
+	!app-crypt/qca-ossl
+	!app-crypt/qca-pkcs11
+	botan? ( dev-libs/botan )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	openssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	pkcs11? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+		dev-libs/pkcs11-helper
+	)
+	qt4? ( dev-qt/qtcore:4 )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtnetwork:5
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? (
+		qt4? ( dev-qt/qttest:4 )
+		qt5? ( dev-qt/qttest:5 )
+	)
+"
+
+DOCS=( README TODO )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-disable-pgp-test.patch"
+)
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_mkspecsdir)/features"
+			-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_plugindir)"
+			$(qca_plugin_use botan)
+			$(qca_plugin_use gcrypt)
+			$(qca_plugin_use gpg gnupg)
+			$(qca_plugin_use logger)
+			$(qca_plugin_use nss)
+			$(qca_plugin_use openssl ossl)
+			$(qca_plugin_use pkcs11)
+			$(qca_plugin_use sasl cyrus-sasl)
+			$(qca_plugin_use softstore)
+			$(cmake-utils_use_build test TESTS)
+		)
+
+		if [[ ${MULTIBUILD_VARIANT} == qt4 ]]; then
+			mycmakeargs+=(-DQT4_BUILD=ON)
+		fi
+
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	mytest() {
+		local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+		cmake-utils_src_test
+	}
+
+	multibuild_foreach_variant mytest
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null || die
+		doxygen Doxyfile.in || die
+		dodoc -r apidocs/html
+		popd >/dev/null || die
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}
-- 
2.26.2