From: Michael Orlitzky <mjo@gentoo.org>
Date: Tue, 26 May 2020 23:27:10 +0000 (-0400)
Subject: sci-mathematics/rw: disable static libs and delete libtool archives.
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=fd15775af4196eefe3748260a6824955773672b0;p=gentoo.git

sci-mathematics/rw: disable static libs and delete libtool archives.

Closes: https://bugs.gentoo.org/725530
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>
---

diff --git a/sci-mathematics/rw/rw-0.8-r3.ebuild b/sci-mathematics/rw/rw-0.8-r3.ebuild
new file mode 100644
index 000000000000..6bbd3085010b
--- /dev/null
+++ b/sci-mathematics/rw/rw-0.8-r3.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Compute rank-width decompositions of graphs"
+HOMEPAGE="https://sourceforge.net/projects/rankwidth/"
+SRC_URI="https://downloads.sourceforge.net/project/rankwidth/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE=""
+
+# We have a file collision (librw.so) with xpaint, bug 560210.
+RDEPEND="!media-gfx/xpaint"
+
+src_prepare() {
+	# The upstream tarball for v0.8 contains SYMLINKS to ar-lib,
+	# compile, install-sh, ltmain.sh, etc. And those symlinks don't
+	# always point to a working location for us, so we have to
+	# (re)generate actual files for that stuff. Bug 696986.
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# The executable depends on igraph, which has gone off the rails
+	# upstream and has copy/pasted ~10 libraries into its src/ directory.
+	econf --disable-executable --disable-static
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete \
+		|| die 'failed to delete libtool archives'
+}