From: Mart Raudsepp <leio@gentoo.org>
Date: Fri, 18 Jan 2019 16:16:09 +0000 (+0200)
Subject: app-crypt/gcr: bump to 3.28.1 for glib-2.59+ compatibility
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=fb64bfadf79439667829b3cb9cd3d037249ace23;p=gentoo.git

app-crypt/gcr: bump to 3.28.1 for glib-2.59+ compatibility

.. and translation updates.

With newer glib (that we don't have in main tree), the old version
would crash gnome-shell after unlocking a SSH key. This bump fixes
that.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index 2c362f4fad40..4694b9bf0ec0 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -1,2 +1,3 @@
 DIST gcr-3.20.0.tar.xz 1324216 BLAKE2B dca283d1bde4994ee60666b2d5fdc4f0861df453355dcf20cea22a87808da0b9284506460ecdfe779ab9ecdf4ce17e231bd1d9426d677511684c35e43da19550 SHA512 0acd0fb085a38507b1cc895ac773f91c6f4e14d2ea7e27b8e74c85ef78426597b6ea08ebee696452b0651939ec4a0d8a4a2523c41b3a8a0bd1b0d7b338b1d9c7
 DIST gcr-3.28.0.tar.xz 1329044 BLAKE2B b35bca9b62605c4e0c3d71604ea5e6b7cdd97bb3257aabb26b8834622abdeec29798429b84f88254a1f8b04894f5cac2ef63c2a0bfd47ad32761d8d73cd0b189 SHA512 8d5e650cb369fa889b0adfdc1dc1cb5f8b184881256e6c0a2ed456074a54ceb61d64c0929c093bec66c0d5a15c1718f6e3736a1b25b6d7076081df93b49419e0
+DIST gcr-3.28.1.tar.xz 1334896 BLAKE2B e7035dd0ac5ef9e9b0898e3e4512768ec7cb548cf0ec4ace5a4f0f9a63d3015f8a041bc6f0a0c990c1666eb92c047eab4c19338a8ccf2d8aa9b11830dbd9d5c5 SHA512 ae36c39584d6bc2ba9d86de8bc71eac21fb3251b966ab1eddf467d01ed5789ba6e6597c83ea2ed9403e632893e7c7cb6c17e04878d726b72528af9199bebb3da
diff --git a/app-crypt/gcr/gcr-3.28.1.ebuild b/app-crypt/gcr/gcr-3.28.1.ebuild
new file mode 100644
index 000000000000..58b6d1814b0a
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.28.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://git.gnome.org/browse/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-3
+
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+COMMON_DEPEND="
+	>=app-crypt/p11-kit-0.19
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3.12:3[X,introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-keyring-3.3
+"
+# gcr was part of gnome-keyring until 3.3
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection-common
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	dev-libs/vala-common
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+#	dev-libs/vala-common
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid flag changes
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
+src_test() {
+	virtx emake check
+}