From: Ralph Seichter <github@seichter.de>
Date: Fri, 27 Mar 2020 21:31:08 +0000 (+0100)
Subject: net-mail/automx2: Depend on dev-python/ldap3
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=f9bf82da2b70f7943f649ef80c18ff089fabe882;p=gentoo.git

net-mail/automx2: Depend on dev-python/ldap3

Add dependency on dev-python/ldap3 which now supports Python 3.7.

Bug: https://bugs.gentoo.org/705714
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Ralph Seichter <gentoo@seichter.de>
Closes: https://github.com/gentoo/gentoo/pull/15142
Signed-off-by: Marc Schiffbauer <mschiff@gentoo.org>
---

diff --git a/net-mail/automx2/automx2-2020.1-r1.ebuild b/net-mail/automx2/automx2-2020.1-r1.ebuild
new file mode 100644
index 000000000000..27bbeeef2a14
--- /dev/null
+++ b/net-mail/automx2/automx2-2020.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Email client autoconfiguration service"
+HOMEPAGE="https://automx.org/"
+SRC_URI="https://gitlab.com/automx/automx2/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc"
+
+BDEPEND="acct-user/automx2
+	dev-python/flask-migrate[${PYTHON_USEDEP}]
+	dev-python/ldap3[${PYTHON_USEDEP}]"
+RDEPEND="${BDEPEND}"
+
+python_prepare_all() {
+	sed -i -e "/('scripts'/d" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	export AUTOMX2_CONF="tests/unittest.conf"
+	${EPYTHON} -m unittest discover tests/ || die
+}
+
+python_install_all() {
+	if use doc; then
+		DOCS="*.adoc doc/*.adoc contrib/*sample.conf"
+		HTML_DOCS="doc/*.html doc/*.svg"
+	fi
+	sed -e "s/@EPYTHON@/${EPYTHON}/" "${FILESDIR}/init" | newinitd - "${PN}"
+	newconfd "${FILESDIR}/confd" "${PN}"
+	insinto /etc
+	newins "${FILESDIR}/conf" "${PN}.conf"
+	distutils-r1_python_install_all
+}