From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Thu, 2 Apr 2020 07:37:49 +0000 (+0100)
Subject: dev-util/xxdiff: drop python code
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=f66dd86475def556af1f7eef01889d80c3ee1a0d;p=gentoo.git

dev-util/xxdiff: drop python code

Python libraries and scripts were never ported from python2.
Let's keep only 'xxdiff' binary itself.

Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---

diff --git a/dev-util/xxdiff/xxdiff-4.0.1_p20170622-r1.ebuild b/dev-util/xxdiff/xxdiff-4.0.1_p20170622-r1.ebuild
new file mode 100644
index 000000000000..f7102a96610a
--- /dev/null
+++ b/dev-util/xxdiff/xxdiff-4.0.1_p20170622-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils
+
+DESCRIPTION="A graphical file and directories comparator and merge tool"
+HOMEPAGE="http://furius.ca/xxdiff/"
+# generated as 'hg archive xxdiff-${P}.tar'
+# from https://bitbucket.org/blais/xxdiff tree
+#SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+SRC_URI="https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+"
+DEPEND="
+	${RDEPEND}
+	virtual/yacc
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0.1-no-throw-in-dtor.patch
+	"${FILESDIR}"/${P}-cxx11.patch
+)
+
+src_configure() {
+	pushd src >/dev/null || die
+		# mimic src/Makefile.bootstrap
+		eqmake5
+		cat Makefile.extra >> Makefile || die
+	popd
+}
+
+src_compile() {
+	emake -C src MAKEDIR=.
+
+	HTML_DOCS+=(
+		doc/*.{png,html}
+		src/doc.html
+	)
+}
+
+src_install() {
+	dobin bin/xxdiff
+
+	dodoc CHANGES README* TODO doc/*.txt src/doc.txt
+
+	# example tools, use these to build your own ones
+	dodoc -r tools
+}