From: Louis Sautier <sbraz@gentoo.org>
Date: Mon, 14 Oct 2019 13:09:14 +0000 (+0200)
Subject: dev-python/jaraco-collections: bump to 2.1
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=f34ff751be1a6971bcb05553837b514064597cef;p=gentoo.git

dev-python/jaraco-collections: bump to 2.1

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Louis Sautier <sbraz@gentoo.org>
---

diff --git a/dev-python/jaraco-collections/Manifest b/dev-python/jaraco-collections/Manifest
index dbfc06ca2a2d..0540b3c7f305 100644
--- a/dev-python/jaraco-collections/Manifest
+++ b/dev-python/jaraco-collections/Manifest
@@ -1,3 +1,4 @@
 DIST jaraco.collections-1.5.3.tar.gz 11669 BLAKE2B 2dbcac99edf28f4544e354724f8d95c0cbcdd793b33bcf892b403e72410f3b5b72b6eae62a49f0e56991cfb19b4ad5da0e95a3327f11fe5ae885e9a0029a92be SHA512 6e1fa88b468b9d971a7a302ebfdf8b9762404c2fdc1b003eee6653704b9f385f0f2e0c84ac075bdc81f8693195781cc5532c4adb31bcabd87974624a14e287ed
 DIST jaraco.collections-1.6.0.tar.gz 11991 BLAKE2B 8f8b3da18641d6348a28ef3792afabd504771f31f1de17ebb621aff493cbb7357e11d49d8b3f4ab4fc7b9a662986d10a90d20734cd802c6d34be1d169390aa96 SHA512 9bd472b51668129f12fabb90b86ed929e135a17217bc850d67d945a786d1952cf1f11b0cd8f5d4ae16b3b19ac35cf87e0584df622877185362e93ba3915dbe6b
 DIST jaraco.collections-2.0.tar.gz 15102 BLAKE2B 61fa35070b2342f95b3e6e571417ab2cd62be439250d8f2077b379316488a4af62d943248bad80d0a72d9aab3010c6982fb4a51fa4ddc574ab72943e37ddeb6b SHA512 1cc3482bddf6647b7fd183f091db7fe89e9ad1ac416716a918626134835837c2ed29d533bc00052a514d64c94343a070b9b501984b3dcc5caac87066d9c335cf
+DIST jaraco.collections-2.1.tar.gz 16026 BLAKE2B b79b57b6bac1e18b6be44ea0e5ad65e46228c7fb4f47be90471cb7a2f85e4c5b10cabe47f1fc6287383b1184db85e5d286d219def3a5f5bfca10e354510d85bb SHA512 64fd3f4155dfc64152dcfb7970c26c7e3e098b0a8282556d17be2aeb80dcac6092b6dca11bf42cda268e0ddda67f2117704c81218c4b6511236e57b1f602da47
diff --git a/dev-python/jaraco-collections/jaraco-collections-2.1.ebuild b/dev-python/jaraco-collections/jaraco-collections-2.1.ebuild
new file mode 100644
index 000000000000..d8aefffd0776
--- /dev/null
+++ b/dev-python/jaraco-collections/jaraco-collections-2.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Models and classes to supplement the stdlib collections module"
+HOMEPAGE="https://github.com/jaraco/jaraco.collections"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	>=dev-python/six-1.7.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -vv --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+# https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
+python_install() {
+	rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+	# note: eclass may default to --skip-build in the future
+	distutils-r1_python_install --skip-build
+}