From: Andrey Grozin <grozin@gentoo.org>
Date: Mon, 7 Sep 2015 12:27:22 +0000 (+0600)
Subject: dev-lisp/sbcl: version bump
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=ec54bbaf40ca65c058854072315fc3eb8ded88ea;p=gentoo.git

dev-lisp/sbcl: version bump

Bug: 559700

Package-Manager: portage-2.2.20.1
---

diff --git a/dev-lisp/sbcl/Manifest b/dev-lisp/sbcl/Manifest
index 3482acabf75b..a3c2b937453a 100644
--- a/dev-lisp/sbcl/Manifest
+++ b/dev-lisp/sbcl/Manifest
@@ -12,6 +12,8 @@ DIST sbcl-1.2.13-source.tar.bz2 5567609 SHA256 e6d93a94cbf821b2c500a9440ca640588
 DIST sbcl-1.2.13-x86-64-linux-binary.tar.bz2 10154344 SHA256 900e58adb9a449e3b5177207908a361de71be1e3aec712aff731ba9a9903f3ab SHA512 483aafc9b38cf317ea764d66e1faf70560cca4c04355ae0a0669692c985034335ec155fc9557acab8cc5f2ee668615985950b2fa96d0acc900b74aceeeafb64c WHIRLPOOL bc9218f7a32194a19b12cd218b2ebfb1dbce01717289241ba62a1b39a424fc2d0620c80b536d1c0a605322e99c52ae0f01d943bd93b7e4c1388ae9b7ab7464bc
 DIST sbcl-1.2.14-source.tar.bz2 5565538 SHA256 b9146dd6460c05bca508f6dda83003580911833eedd51dbc09d8eca80b0f5c06 SHA512 471b215419f9303e010cbfb99866e09a43cc68a63680b5267662a12585b145b9f520592c37c81eabfe81b102255cd82fabb74cca731d8c3eed50747df34a6e2c WHIRLPOOL e89cd4c2ff1b2716c0ba62aed6d2107f05094c053c91db8a14638a80a5b63f83102fc1c125164edf251ed2ca507e00c298a9278efe83ad5f3b27ab53ddd48131
 DIST sbcl-1.2.14-x86-64-linux-binary.tar.bz2 9723047 SHA256 e06a43a3490a2d9239b55a0e64b8c46d285ea509a940456013bfe90ba6a2dd2c SHA512 7c079c68104a44fd004b371f533502f478a7294b5577c7fd900adcdf22be1a18bdedeab3be259606c059d14c38c639f061866969ccd56e24fe64198dd96bf20c WHIRLPOOL 738f20eeeb50aef368c7fcdb7979a4c10f72f5889a9e7e0220a48be54d57f141ea0b2b59e10422878b227d5bdfe57eecaacdd6b3936a30535453c96925099806
+DIST sbcl-1.2.15-source.tar.bz2 5585753 SHA256 d95a6e8a4b658f9973825f8d44d6195a645b0d6a33d865324c0c658b8bcb1651 SHA512 a34947cff6d8e54068942df307a84a755d2ddb549d2da394545d3d37a821a8cccc3f4cab30741948e000c06bb3e422963e29a349007143a64bb97cc013c45771 WHIRLPOOL 13b413327525961f29dac6f91fb100383a3be515abc1db0255d94b5c1448b0f749defa5a36033883b57747412f5ec4646e303260f39ce7caa4f73dbea82ff231
+DIST sbcl-1.2.15-x86-64-linux-binary.tar.bz2 9799234 SHA256 5c1db23dfa6b8d2c0a66fe0b08928dd7dc50499be022388587e370d1d377ebae SHA512 15d4173d80b38f3dc32445a605e95618dd02386ca007e162b36a2f5808ab7f925f8246ccb4a68b02ec5d09af74919818ca2254e6593862b074f4b715796fc8ca WHIRLPOOL 29d40cb1c7c2af4a4b4666dacb373fc8af82fe95f058ca54d9232e75c957803d5b20338d74f37b87de05ce395b8954c2c89ed90d95a29570b40fcd76df4b634b
 DIST sbcl-1.2.7-armhf-linux-binary.tar.bz2 9914851 SHA256 5e75a328882b739befcf5c38e8039b830668a8ca7bafe56a9e13ef23f39eb253 SHA512 2c82bdfe4f070a43964e694f81ccdbb84f8dd3bf77c807343daadff877b518fcd52e05513691543ca076c2b6de8bcf8b2e672b31f5ed3f545bedb02bbf7cd868 WHIRLPOOL 8e0eab53a9bfe10a1ccaa5c950e9fe045aeaa23f9f66ca98badd5a0fce3ad5828c0059904c73584dd4591fb3f9b2eefb5210a19f2de9fd8d699d48b0cee3bbef
 DIST sbcl-1.2.7-powerpc-linux-binary.tar.bz2 9884585 SHA256 d2f86db4f6fe2b6e6bbc6353ce28dead1b142ed36885080b97304db55aae2861 SHA512 7b9fef12d3d6397adec6a0c26d1431a18b8d91b5bf009034eb2501de9fd60dc04dd2e3cd2d9feb9204d4631360aea88ba07a9ad75dad0767b5dcc5e62e84e790 WHIRLPOOL 4b884ab946e8c54775970aa502054f42a92d01257449796c7d1a6bd1ff5835ddae1c94aa5d936a7a5b115183c6cee5251034646559e4435a6663896fa302c4be
 DIST sbcl-1.2.7-x86-64-solaris-binary.tar.bz2 10438955 SHA256 a0a13e83b35dbac36284459747a03c6db20cd089864e16a6380a12a6aa138115 SHA512 9566cebf8fc29ead1f919309e3f98aeb618e97b34c80f53d1f739f1a3f4ef4cbaebd1c67f0b32172a0cdf14dc405eb75d0e916dedf3b8a758cdec2368d25f5c1 WHIRLPOOL 4946b9a4463c92517233298f898510ca57b4127da93d7d42cf28005bbd96b8d1eba7472f73029f45d6c0e75f3de5b893a34f33feee92a60cef8ae4f2b4d4fa0e
diff --git a/dev-lisp/sbcl/sbcl-1.2.15.ebuild b/dev-lisp/sbcl/sbcl-1.2.15.ebuild
new file mode 100644
index 000000000000..fd1bea7afdfa
--- /dev/null
+++ b/dev-lisp/sbcl/sbcl-1.2.15.ebuild
@@ -0,0 +1,236 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit multilib eutils flag-o-matic pax-utils
+
+#same order as http://www.sbcl.org/platform-table.html
+BV_X86=1.2.7
+BV_AMD64=1.2.15
+BV_PPC=1.2.7
+BV_SPARC=1.0.28
+BV_ALPHA=1.0.28
+BV_ARM=1.2.7
+BV_PPC_MACOS=1.0.47
+BV_X86_MACOS=1.1.6
+BV_X64_MACOS=1.1.8
+BV_SPARC_SOLARIS=1.0.23
+BV_X86_SOLARIS=1.2.7
+BV_X64_SOLARIS=1.2.7
+
+DESCRIPTION="Steel Bank Common Lisp (SBCL) is an implementation of ANSI Common Lisp"
+HOMEPAGE="http://sbcl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sbcl/${P}-source.tar.bz2
+	x86? ( mirror://sourceforge/sbcl/${PN}-${BV_X86}-x86-linux-binary.tar.bz2 )
+	amd64? ( mirror://sourceforge/sbcl/${PN}-${BV_AMD64}-x86-64-linux-binary.tar.bz2 )
+	ppc? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC}-powerpc-linux-binary.tar.bz2 )
+	sparc? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC}-sparc-linux-binary.tar.bz2 )
+	alpha? ( mirror://sourceforge/sbcl/${PN}-${BV_ALPHA}-alpha-linux-binary.tar.bz2 )
+	arm? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM}-armhf-linux-binary.tar.bz2 )
+	ppc-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC_MACOS}-powerpc-darwin-binary.tar.bz2 )
+	x86-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_X86_MACOS}-x86-darwin-binary.tar.bz2 )
+	x64-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_MACOS}-x86-64-darwin-binary.tar.bz2 )
+	sparc-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC_SOLARIS}-sparc-solaris-binary.tar.bz2 )
+	x86-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X86_SOLARIS}-x86-solaris-binary.tar.bz2 )
+	x64-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_SOLARIS}-x86-64-solaris-binary.tar.bz2 )"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="debug doc source +threads +unicode pax_kernel zlib"
+
+CDEPEND=">=dev-lisp/asdf-3.1:="
+DEPEND="${CDEPEND}
+		doc? ( sys-apps/texinfo >=media-gfx/graphviz-2.26.0 )
+		pax_kernel? ( sys-apps/paxctl sys-apps/elfix )"
+RDEPEND="${CDEPEND}
+		!prefix? ( elibc_glibc? ( >=sys-libs/glibc-2.6 ) )"
+
+# Disable warnings about executable stacks, as this won't be fixed soon by upstream
+QA_EXECSTACK="usr/bin/sbcl"
+
+CONFIG="${S}/customize-target-features.lisp"
+ENVD="${T}/50sbcl"
+
+# Prevent ASDF from using the system libraries
+CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)"
+ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)"
+
+usep() {
+	use ${1} && echo "true" || echo "false"
+}
+
+sbcl_feature() {
+	echo "$( [[ ${1} == "true" ]] && echo "(enable ${2})" || echo "(disable ${2})")" >> "${CONFIG}"
+}
+
+sbcl_apply_features() {
+	sed 's/^X//' > "${CONFIG}" <<-'EOF'
+	(lambda (list)
+	X  (flet ((enable  (x) (pushnew x list))
+	X         (disable (x) (setf list (remove x list))))
+	EOF
+	if use x86 || use amd64; then
+		sbcl_feature "$(usep threads)" ":sb-thread"
+	fi
+	sbcl_feature "true" ":sb-ldb"
+	sbcl_feature "false" ":sb-test"
+	sbcl_feature "$(usep unicode)" ":sb-unicode"
+	sbcl_feature "$(usep zlib)" ":sb-core-compression"
+	sbcl_feature "$(usep debug)" ":sb-xref-for-internals"
+	sed 's/^X//' >> "${CONFIG}" <<-'EOF'
+	X    )
+	X  list)
+	EOF
+	cat "${CONFIG}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv sbcl-*-* sbcl-binary || die
+	cd "${S}"
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/gentoo-fix_install_man.patch
+	# bug #468482
+	epatch "${FILESDIR}"/concurrency-test-1.2.6.patch
+	# bugs #486552, #527666, #517004
+	epatch "${FILESDIR}"/bsd-sockets-test-1.2.11.patch
+
+	epatch "${FILESDIR}"/${PN}-1.2.11-solaris.patch
+	epatch "${FILESDIR}"/${PN}-1.2.13-verbose-build.patch
+
+	# To make the hardened compiler NOT compile with -fPIE -pie
+	if gcc-specs-pie ; then
+		einfo "Disabling PIE..."
+		epatch "${FILESDIR}"/${PN}-1.1.17-gentoo-fix_nopie_for_hardened_toolchain.patch
+	fi
+
+	# bug #526194
+	sed -e "s@CFLAGS =.*\$@CFLAGS = ${CFLAGS} -g -Wall -Wsign-compare@" \
+		-e "s@LINKFLAGS =.*\$@LINKFLAGS = ${LDFLAGS} -g@" \
+		-i src/runtime/GNUmakefile || die
+
+	sed -e "s@SBCL_PREFIX=\"/usr/local\"@SBCL_PREFIX=\"${EPREFIX}/usr\"@" \
+		-i make-config.sh || die
+
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+
+	use source && sed 's%"$(BUILD_ROOT)%$(MODULE).lisp "$(BUILD_ROOT)%' -i contrib/vanilla-module.mk
+
+	# Some shells(such as dash) don't have "time" as builtin
+	# and we don't want to DEPEND on sys-process/time
+	sed "s,^time ,," -i make.sh || die
+	sed "s,/lib,/$(get_libdir),g" -i install.sh || die
+	# #define SBCL_HOME ...
+	sed "s,/usr/local/lib,${EPREFIX}/usr/$(get_libdir),g" -i src/runtime/runtime.c || die
+	# change location of /etc/sbclrc ...
+	sed  "s,/etc/sbclrc,${EPREFIX}/etc/sbclrc,g" -i src/code/toplevel.lisp || die
+
+	find . -type f -name .cvsignore -delete
+}
+
+src_configure() {
+	# customizing SBCL version as per
+	# http://sbcl.cvs.sourceforge.net/sbcl/sbcl/doc/PACKAGING-SBCL.txt?view=markup
+	echo -e ";;; Auto-generated by Gentoo\n\"gentoo-${PR}\"" > branch-version.lisp-expr
+
+	# applying customizations
+	sbcl_apply_features
+}
+
+src_compile() {
+	local bindir="${WORKDIR}"/sbcl-binary
+
+	strip-unsupported-flags ; filter-flags -fomit-frame-pointer
+
+	if host-is-pax ; then
+		# To disable PaX on hardened systems
+		pax-mark -mr "${bindir}"/src/runtime/sbcl
+
+		# Hack to disable PaX on second GENESIS stage
+		sed -i -e '/^[ \t]*echo \/\/doing warm init - compilation phase$/a\    paxmark.sh -mr \.\/src\/runtime\/sbcl' \
+			"${S}"/make-target-2.sh || die "Cannot disable PaX on second GENESIS runtime"
+	fi
+
+	# clear the environment to get rid of non-ASCII strings, see bug 174702
+	# set HOME for paludis
+	env - HOME="${T}" PATH="${PATH}" \
+		CC="$(tc-getCC)" AS="$(tc-getAS)" LD="$(tc-getLD)" \
+		CPPFLAGS="${CPPFLAGS}" CFLAGS="${CFLAGS}" ASFLAGS="${ASFLAGS}" LDFLAGS="${LDFLAGS}" \
+		GNUMAKE=make ./make.sh \
+		"sh ${bindir}/run-sbcl.sh --no-sysinit --no-userinit --disable-debugger" \
+		|| die "make failed"
+
+	# need to set HOME because libpango(used by graphviz) complains about it
+	if use doc; then
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/manual info html || die "Cannot build manual"
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/internals info html || die "Cannot build internal docs"
+	fi
+}
+
+src_test() {
+	ewarn "Unfortunately, it is known that some tests fail eg."
+	ewarn "run-program.impure.lisp. This is an issue of the upstream's"
+	ewarn "development and not of Gentoo's side. Please, before filing"
+	ewarn "any bug(s) search for older submissions. Thank you."
+	time ( cd tests && sh run-tests.sh )
+}
+
+src_install() {
+	# install system-wide initfile
+	dodir /etc/
+	sed 's/^X//' > "${ED}"/etc/sbclrc <<-EOF
+	;;; The following is required if you want source location functions to
+	;;; work in SLIME, for example.
+	X
+	(setf (logical-pathname-translations "SYS")
+	X      '(("SYS:SRC;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/src/**/*.*")
+	X        ("SYS:CONTRIB;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/**/*.*")))
+	X
+	;;; Setup ASDF2
+	(load "${EPREFIX}/etc/common-lisp/gentoo-init.lisp")
+	EOF
+
+	# Install documentation
+	unset SBCL_HOME
+	INSTALL_ROOT="${ED}/usr" LIB_DIR="${EPREFIX}/usr/$(get_libdir)" DOC_DIR="${ED}/usr/share/doc/${PF}" \
+		sh install.sh || die "install.sh failed"
+
+	# bug #517008
+	pax-mark -mr "${D}"/usr/bin/sbcl
+
+	# rm empty directories lest paludis complain about this
+	find "${ED}" -empty -type d -exec rmdir -v {} +
+
+	if use doc; then
+		dohtml -r doc/manual/
+		doinfo doc/manual/*.info*
+		dohtml -r doc/internals/sbcl-internals
+		doinfo doc/internals/sbcl-internals.info
+		docinto internals-notes && dodoc doc/internals-notes/*
+	else
+		rm -Rv "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	dodoc BUGS CREDITS INSTALL NEWS OPTIMIZATIONS PRINCIPLES README TLA TODO
+
+	# install the SBCL source
+	if use source; then
+		./clean.sh
+		cp -av src "${ED}/usr/$(get_libdir)/sbcl/" || die
+	fi
+
+	# necessary for running newly-saved images
+	echo "SBCL_HOME=${EPREFIX}/usr/$(get_libdir)/${PN}" > "${ENVD}"
+	echo "SBCL_SOURCE_ROOT=${EPREFIX}/usr/$(get_libdir)/${PN}/src" >> "${ENVD}"
+	doenvd "${ENVD}"
+}