From: Julian Ospald <hasufell@gentoo.org>
Date: Wed, 30 Sep 2015 20:21:07 +0000 (+0200)
Subject: net-libs/gloox: add libressl support
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=eb6fbf62bf7d65bc52b63f2437ad861d4d31b734;p=gentoo.git

net-libs/gloox: add libressl support
---

diff --git a/net-libs/gloox/gloox-1.0.14-r1.ebuild b/net-libs/gloox/gloox-1.0.14-r1.ebuild
new file mode 100644
index 000000000000..c5b46967ba27
--- /dev/null
+++ b/net-libs/gloox/gloox-1.0.14-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils
+
+MY_P="${P/_/-}"
+DESCRIPTION="A portable high-level Jabber/XMPP library for C++"
+HOMEPAGE="http://camaya.net/gloox"
+SRC_URI="http://camaya.net/download/${MY_P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0/13"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~ia64 ~sparc ~x86"
+IUSE="debug gnutls idn libressl ssl static-libs test zlib"
+
+DEPEND="idn? ( net-dns/libidn )
+	gnutls? ( net-libs/gnutls )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	zlib? ( sys-libs/zlib )"
+
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch_user
+}
+
+src_configure() {
+	# Examples are not installed anyway, so - why should we build them?
+	econf \
+		--without-examples \
+		$(use debug && echo "--enable-debug") \
+		$(use_enable static-libs static) \
+		$(use_with idn libidn) \
+		$(use_with gnutls) \
+		$(use_with ssl openssl) \
+		$(use_with test tests) \
+		$(use_with zlib)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}