From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Thu, 14 Nov 2019 08:04:08 +0000 (+0100)
Subject: net-misc/nextcloud-client: 2.6.1 bump
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=eb4be629c200a6e3c741f667046d46d3b9c0483f;p=gentoo.git

net-misc/nextcloud-client: 2.6.1 bump

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index e530f1d4a594..b66266a125f1 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST nextcloud-client-2.5.2.tar.gz 18995992 BLAKE2B 6ad23962d327c1feeec34f59092021f7f82f4baeaf973fac0572db55cb03bc8ba2ed0c5037bcbfa80ca057d3976aaf6e402e129f2ec963b3a9c432330ef6aaf3 SHA512 1000b420355d7a4104ca5b41e813d467dcb345b60c79c78ce532de9c58ea89cad10d5565a433409bd512f0f7771c18c7c27974b968c74f84ccfda1ed3510d3ae
 DIST nextcloud-client-2.6.0.tar.gz 18789917 BLAKE2B db5c703ecf630a96c141c9c8a7b15894c5a679e1b36217f38a02cd55307fadb5ea19c13ab44371fbbcf0610ddafdd2fb0c1ef6119db04808b94a72dbfb27da9a SHA512 161733540de85c436e204b150fb91b527737fee213e569335248ce7c6e1446497aad5e3fa814b3f98a1ec0cdb94fad64ccc0807eb953a94170f9d40abb478545
+DIST nextcloud-client-2.6.1.tar.gz 18947504 BLAKE2B 940145f9f633ad35e740a92d44d0d7172f7c0883bf29951694dd540213dcfc64f9d480a1cd38b586842dad8c96d3c2948d6e8af6042005f0cd23d9b6d3eab7c6 SHA512 dbda59f5ef6f5f85d8344732be4a0b51e51fa9d0180d5b589f79ab6fe1bacf3a63879aee2f297bc76d6257dd830b38c695cf88f98b9e3f788acf9d6b2f11f619
diff --git a/net-misc/nextcloud-client/nextcloud-client-2.6.1.ebuild b/net-misc/nextcloud-client/nextcloud-client-2.6.1.ebuild
new file mode 100644
index 000000000000..e931c2d92649
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-2.6.1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}