From: Sergey Popov <pinkbyte@gentoo.org>
Date: Wed, 27 Jan 2016 08:48:59 +0000 (+0300)
Subject: dev-libs/xmlwrapp: revision bump
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=d12887e32fcbe3c1e080dfe42534f7ed825128d7;p=gentoo.git

dev-libs/xmlwrapp: revision bump

Bump EAPI to 6, add multilib support. Unbundle boost-m4,
which effectively fix building with GCC 5

Gentoo-Bug: 571502

Package-Manager: portage-2.2.26
---

diff --git a/dev-libs/xmlwrapp/xmlwrapp-0.7.1-r1.ebuild b/dev-libs/xmlwrapp/xmlwrapp-0.7.1-r1.ebuild
new file mode 100644
index 000000000000..696025dee7b2
--- /dev/null
+++ b/dev-libs/xmlwrapp/xmlwrapp-0.7.1-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="modern style C++ library that provides a simple and easy interface to libxml2"
+HOMEPAGE="http://vslavik.github.io/xmlwrapp/"
+SRC_URI="https://github.com/vslavik/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="static-libs"
+
+RDEPEND="dev-libs/boost:=[${MULTILIB_USEDEP}]
+	dev-libs/libxml2[${MULTILIB_USEDEP}]
+	dev-libs/libxslt[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	sys-devel/boost-m4"
+
+DOCS=( AUTHORS NEWS README )
+
+src_prepare() {
+	# Unbundle boost.m4
+	rm admin/boost.m4 || die
+
+	sed -i -e '/XMLWRAPP_VISIBILITY/d' configure.ac || die
+
+	eapply_user
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local ECONF_SOURCE=${BUILD_DIR}
+	econf $(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	default_src_install
+	prune_libtool_files
+}