From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Wed, 1 Apr 2020 21:04:09 +0000 (+0100)
Subject: sys-fs/diskdev_cmds: use relative symlinks in /sbin
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=cb8a551aae61a74acefe9faf2e0f8e2b4526275e;p=gentoo.git

sys-fs/diskdev_cmds: use relative symlinks in /sbin

Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---

diff --git a/sys-fs/diskdev_cmds/diskdev_cmds-332.14_p1-r2.ebuild b/sys-fs/diskdev_cmds/diskdev_cmds-332.14_p1-r2.ebuild
new file mode 100644
index 000000000000..b4a3180e1b42
--- /dev/null
+++ b/sys-fs/diskdev_cmds/diskdev_cmds-332.14_p1-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_PV=${PV%_p*}
+
+DESCRIPTION="HFS and HFS+ utils ported from OSX, supplies mkfs and fsck"
+HOMEPAGE="http://opendarwin.org"
+SRC_URI="http://darwinsource.opendarwin.org/tarballs/apsl/diskdev_cmds-${MY_PV}.tar.gz
+		 mirror://gentoo/diskdev_cmds-${PV}.patch.bz2"
+LICENSE="APSL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE=""
+DEPEND="dev-libs/openssl"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+PATCHES=(
+	"${WORKDIR}"/diskdev_cmds-${PV}.patch
+	"${FILESDIR}"/diskdev_cmds-respect-cflags.patch
+)
+
+src_compile() {
+	emake -f Makefile.lnx AR="$(tc-getAR)" CC="$(tc-getCC)"
+}
+
+src_install() {
+	into /
+
+	dosbin fsck_hfs.tproj/fsck_hfs
+	dosbin newfs_hfs.tproj/newfs_hfs
+
+	dosym newfs_hfs /sbin/mkfs.hfs
+	dosym newfs_hfs /sbin/mkfs.hfsplus
+	dosym fsck_hfs /sbin/fsck.hfs
+	dosym fsck_hfs /sbin/fsck.hfsplus
+	doman newfs_hfs.tproj/newfs_hfs.8
+
+	newman newfs_hfs.tproj/newfs_hfs.8 mkfs.hfs.8
+	newman newfs_hfs.tproj/newfs_hfs.8 mkfs.hfsplus.8
+	doman fsck_hfs.tproj/fsck_hfs.8
+	newman fsck_hfs.tproj/fsck_hfs.8 fsck.hfs.8
+	newman fsck_hfs.tproj/fsck_hfs.8 fsck.hfsplus.8
+}