From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Sat, 2 May 2020 12:18:35 +0000 (+0100)
Subject: app-arch/sharutils: bump up to EAPI=7
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=b58b000f7c7f792561bdf7b160d9be5711a0462c;p=gentoo.git

app-arch/sharutils: bump up to EAPI=7

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---

diff --git a/app-arch/sharutils/sharutils-4.15.2-r2.ebuild b/app-arch/sharutils/sharutils-4.15.2-r2.ebuild
new file mode 100644
index 000000000000..2aaa0c101dea
--- /dev/null
+++ b/app-arch/sharutils/sharutils-4.15.2-r2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit eutils flag-o-matic
+
+MY_P="${P/_/-}"
+DESCRIPTION="Tools to deal with shar archives"
+HOMEPAGE="https://www.gnu.org/software/sharutils/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="nls"
+
+DEPEND="app-arch/xz-utils
+	sys-apps/texinfo
+	nls? ( >=sys-devel/gettext-0.10.35 )"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.15.2-glibc228.patch
+	"${FILESDIR}"/${PN}-4.15.2-CVE-2018-1000097.patch
+	"${FILESDIR}"/${PN}-4.15.2-gcc-10.patch
+)
+
+src_prepare() {
+	default
+
+	# Upstream is aware but thinks this isn't a bug/problem in sharutils itself
+	# See http://lists.gnu.org/archive/html/bug-gnu-utils/2013-10/msg00011.html
+	append-cflags $(test-flags-CC -Wno-error=format-security)
+}
+
+src_configure() {
+	strip-linguas -u po
+	econf $(use_enable nls)
+}