From: Michał Górny <mgorny@gentoo.org>
Date: Thu, 30 Apr 2020 06:56:45 +0000 (+0200)
Subject: dev-python/pyro: Bump to 4.80
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=b52e1874bdea93ff0b90b4c3ade109195efd6f39;p=gentoo.git

dev-python/pyro: Bump to 4.80

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---

diff --git a/dev-python/pyro/Manifest b/dev-python/pyro/Manifest
index 093f5db1b3c3..7543f3651868 100644
--- a/dev-python/pyro/Manifest
+++ b/dev-python/pyro/Manifest
@@ -1,2 +1,3 @@
 DIST Pyro4-4.77.tar.gz 479025 BLAKE2B 20c7b53cea55b77efea11cd7b74a1cfcc45ad721ba45e039947f1d869291bfcb054f16bc48fb5ad21386fe7d47785514ff94953b1bcf893266c2c41015bba589 SHA512 52a9f90cec8c5e23ec30ddb69484a15bb86d61024d1bc718d075e01678a3d9655a1ed21f18da1891c121bf0e95282fb1151762b2fdb826a6408056079d2b1a66
 DIST Pyro4-4.79.tar.gz 490917 BLAKE2B 421fa2d0b32c27c44d11adb7c89e24cfd7a79c10ae40827407d3d8965e98b7d5126168e5b00b042c4bd94800d3e73fc8febdbbbf2b82d3046584ea88106c4734 SHA512 03e75537c7943e1044b7e6623ead934e3004b023ffc6d364472868e0895e3819c4b3c92d1610018ab1466262f32681e69a91d360c33b17e687861c8c742bdf72
+DIST Pyro4-4.80.tar.gz 515103 BLAKE2B 5d2b69ba020117947a36c9c75f884434a3452167fa2e586e3a5b0e6deb1d0c8c54dd06a20b9568b53a0a6c42a847d880636e3abe37090246d5f34ca84e915b36 SHA512 8e41285674edbe5c8d5ac63e33406c5ff7b6366d5dd251a1755eff81611193278a473ed8b15f995bc0ba2775dc5d316eb6a3cafd63626b95820591ea3a0a92e3
diff --git a/dev-python/pyro/pyro-4.80.ebuild b/dev-python/pyro/pyro-4.80.ebuild
new file mode 100644
index 000000000000..456079265b51
--- /dev/null
+++ b/dev-python/pyro/pyro-4.80.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="https://pypi.org/project/Pyro4/
+	https://github.com/irmen/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~arm64 ~ppc ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!dev-python/pyro:0
+	>=dev-python/serpent-1.27[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
+		dev-python/dill[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.4.6[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Disable tests requiring network connection.
+	rm tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}