From: Jeroen Roovers <jer@gentoo.org>
Date: Sun, 2 Dec 2018 20:18:07 +0000 (+0100)
Subject: net-misc/youtube-dl: Version 2018.12.03
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=a5e71b0072540af05f3efd4fad0dd8504a031224;p=gentoo.git

net-misc/youtube-dl: Version 2018.12.03

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 9d9cbd38be45..df02a0b87a18 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1,2 +1,3 @@
 DIST youtube-dl-2018.11.18.tar.gz 3057924 BLAKE2B eb995cd269c3febcda950d87466df85a31128aaf95dbbd1cb9ee3d329610ffae3194c57f5063b47e49de3e387b5f60a5e10c237dc5d944ce47a6cffacab31935 SHA512 47e503c18f2db948beeda6a61b034953fab61d7d122641be7564a0f6dc0fe66ff93d6ef436c2acbcaf7255248a0b53e4df8c5ed1efca1139dc518a3ffacb737d
 DIST youtube-dl-2018.11.23.tar.gz 3061698 BLAKE2B 6219f7fda9f24bc4e2bc3706e94ae0c2a507d76d3b027dd36d78960e8517cc66049bc520ee774902bd4f05f43b3534da18bd59f4fef12417191e37a7e0fe2c9d SHA512 d4d2813657972c37d3493743a44055d7a776aeb5c5a97902e07caa317a3b2db30332507c37b56b3d8554e0bdc2a0ec6a9862977b449b363343a4de2df12bf059
+DIST youtube-dl-2018.12.03.tar.gz 3065234 BLAKE2B bbf8a7e9f9356df7bbf83cc7074d90814e1f0e7165f61d32616b25f515a3219b59c55708568fc1394c79170583dd9a9d22b1221b42991d0480144baf351b45ef SHA512 5c2b524613ba48003a86ed453983cea2eb8fb26f1137dd776577e0f714fc81f46a45dae59ebccd77695aa0267947c359792d98da0a12ac7242fdd2059f1fcb0f
diff --git a/net-misc/youtube-dl/youtube-dl-2018.12.03.ebuild b/net-misc/youtube-dl/youtube-dl-2018.12.03.ebuild
new file mode 100644
index 000000000000..29fd6bd3825f
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2018.12.03.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://rg3.github.com/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="+offensive test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-python/nose[coverage(+)] )
+"
+
+S="${WORKDIR}/${PN}"
+
+python_prepare_all() {
+	if ! use offensive; then
+		sed -i -e "/..version../s|'$|+gentoo.no.offensive.sites'|g" \
+			youtube_dl/version.py || die
+		# these have single line import statements
+		local xxx=(
+			alphaporno anysex behindkink camwithher chaturbate eporner
+			eroprofile extremetube foxgay goshgay hellporno hentaistigma
+			hornbunny keezmovies lovehomeporn mofosex myvidster porn91 porncom
+			pornflip pornhd pornotube pornovoisines pornoxo ruleporn sexu
+			slutload spankbang spankwire sunporno thisav vporn watchindianporn
+			xbef xnxx xtube xvideos xxxymovies youjizz youporn
+		)
+		# these have multi-line import statements
+		local mxxx=(
+			drtuber fourtube motherless pornhub redtube tnaflix tube8 xhamster
+		)
+		# do single line imports
+		sed -i \
+			-e $( printf '/%s/d;' ${xxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		# do multiple line imports
+		sed -i \
+			-e $( printf '/%s/,/)/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		sed -i \
+			-e $( printf '/%s/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/generic.py \
+			|| die
+
+		rm \
+			$( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
+			$( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
+			test/test_age_restriction.py \
+			|| die
+	fi
+
+	eapply_user
+
+	distutils-r1_python_prepare_all
+}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake test
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}