From: W. Trevor King <wking@tremily.us>
Date: Mon, 29 Sep 2014 23:06:31 +0000 (-0700)
Subject: dev-python/pyvows: Add this (indirect) thumbor test dependency
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=a5136b5958c5a181c7fe39f5b3aa7827da861b4c;p=wtk-overlay.git

dev-python/pyvows: Add this (indirect) thumbor test dependency

I've submitted the find_packages sed upstream [1].  I don't know if
the package itself is compatible with Python 3, but the test suite
isn't so I'm sticking with 2.7 in PYTHON_COMPAT [2].  The test suite
also depends on gevent, because the fallback VowsSequentialRunner is
broken [3].

[1]: https://github.com/heynemann/pyvows/pull/109
[2]: https://github.com/heynemann/pyvows/issues/110#issuecomment-57243488
[3]: https://github.com/heynemann/pyvows/issues/111
---

a5136b5958c5a181c7fe39f5b3aa7827da861b4c
diff --git a/pyvows-9999.ebuild b/pyvows-9999.ebuild
new file mode 100644
index 0000000..4846d58
--- /dev/null
+++ b/pyvows-9999.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/heynemann/${PN}.git"
+	SRC_URI=""
+else
+	SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="A test engine based on Vows.js"
+HOMEPAGE="http://pyvows.org/ https://pypi.python.org/pypi/pyvows"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/gevent-0.13.6[${PYTHON_USEDEP}]
+	>=dev-python/preggy-0.11.1[${PYTHON_USEDEP}]
+	"
+DEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	sed -i "s/packages=find_packages()/packages=find_packages(exclude=['tests', 'tests.*'])/" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" -c 'import coverage; coverage.main()' run --source=pyvows ./pyvows/__main__.py ||
+		die "tests failed with ${EPYTHON}"
+}