From: Matthew Turnbull <sparky@bluefang-logic.com>
Date: Wed, 13 May 2020 03:35:55 +0000 (-0400)
Subject: gnome-extra/cinnamon-session: 4.4.1 version bump
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=a3bfca11205ac906c7cd637babb8b6919f39da83;p=gentoo.git

gnome-extra/cinnamon-session: 4.4.1 version bump

Update cinnamon-session to 4.4.1. Switch to EAPI=7
and clean up eclass usage and dependencies.

Bug: https://bugs.gentoo.org/704532
Closes: https://bugs.gentoo.org/680808
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>
---

diff --git a/gnome-extra/cinnamon-session/Manifest b/gnome-extra/cinnamon-session/Manifest
index 2740a99a1631..e31cf1895b8e 100644
--- a/gnome-extra/cinnamon-session/Manifest
+++ b/gnome-extra/cinnamon-session/Manifest
@@ -1 +1,2 @@
 DIST cinnamon-session-4.0.0.tar.gz 198396 BLAKE2B 713573d445f09cfa4707c3ccaff04bdcc95ea7b60568fc136359258022af287df66992444da462f0488dc4049036deb190523695e519eb61329e922e05871c39 SHA512 7e91bef4e294175fa3333a96d0cb9d06db36c9b5a86d6e52734447ea62d411535760fc46713961a46299ebeb3767a0abd4768279e9f6c176ae882de9b7aedc5e
+DIST cinnamon-session-4.4.1.tar.gz 198819 BLAKE2B bd39b5a89011942239beb76976b01234eaf839e80f1f54d26e1ee988797596d876d2708bee91d4c016a584d76fd9ba1209b4f8e77da8e9db8d7a8b4e5a43dac1 SHA512 f5caf7a3797ca30c397433ea052b7736308a31da291442f64224f034a6bd50eb45307cc8987efe5148eb816c2c70c3033795290386c93f205684796d03b63c22
diff --git a/gnome-extra/cinnamon-session/cinnamon-session-4.4.1.ebuild b/gnome-extra/cinnamon-session/cinnamon-session-4.4.1.ebuild
new file mode 100644
index 000000000000..01a4029bbcbd
--- /dev/null
+++ b/gnome-extra/cinnamon-session/cinnamon-session-4.4.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit meson gnome2-utils xdg
+
+DESCRIPTION="Cinnamon session manager"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/"
+SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc elogind ipv6 systemd"
+REQUIRED_USE="^^ ( elogind systemd )"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	media-libs/libcanberra
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3:3
+	x11-libs/cairo
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango[X]
+	>=x11-libs/xapps-1.0.4
+	virtual/opengl
+	systemd? ( >=sys-apps/systemd-183 )
+	elogind? ( sys-auth/elogind[policykit] )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-extra/cinnamon-desktop-4.4
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	>=dev-util/intltool-0.40.6
+	virtual/pkgconfig
+	doc? (
+		app-text/xmlto
+		dev-libs/libxslt )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.8.0-elogind.patch
+	"${FILESDIR}"/${PN}-3.8.0-elogind2.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		-Dgconf=false
+		$(meson_use doc docbook)
+		$(meson_use ipv6)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/gnome-extra/cinnamon-session/metadata.xml b/gnome-extra/cinnamon-session/metadata.xml
index 9739e1997aa1..d285b2fb0987 100644
--- a/gnome-extra/cinnamon-session/metadata.xml
+++ b/gnome-extra/cinnamon-session/metadata.xml
@@ -5,6 +5,14 @@
 		<email>cinnamon@gentoo.org</email>
 		<name>Cinnamon Project</name>
 	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>sparky@bluefang-logic.com</email>
+		<name>Matthew Turnbull</name>
+	</maintainer>
 	<use>
 		<flag name="elogind">Rely on <pkg>sys-auth/elogind</pkg> as runtime logind provider</flag>
 	</use>