From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 26 Feb 2020 22:27:21 +0000 (+0100)
Subject: dev-qt/qtmultimedia: Drop 5.13.2 (r0)
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=a167f1f22c233042e295a5d1c9724c9bdf9c1465;p=gentoo.git

dev-qt/qtmultimedia: Drop 5.13.2 (r0)

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---

diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.13.2.ebuild b/dev-qt/qtmultimedia/qtmultimedia-5.13.2.ebuild
deleted file mode 100644
index 349dd584a74c..000000000000
--- a/dev-qt/qtmultimedia/qtmultimedia-5.13.2.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-inherit qt5-build
-
-DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
-
-if [[ ${QT5_BUILD_TYPE} == release ]]; then
-	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
-fi
-
-IUSE="alsa gles2 gstreamer openal pulseaudio qml widgets"
-
-RDEPEND="
-	~dev-qt/qtcore-${PV}
-	~dev-qt/qtgui-${PV}[gles2=]
-	~dev-qt/qtnetwork-${PV}
-	alsa? ( media-libs/alsa-lib )
-	gstreamer? (
-		dev-libs/glib:2
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-bad:1.0
-		media-libs/gst-plugins-base:1.0
-	)
-	pulseaudio? ( media-sound/pulseaudio[glib] )
-	qml? (
-		~dev-qt/qtdeclarative-${PV}
-		gles2? ( ~dev-qt/qtgui-${PV}[egl] )
-		openal? ( media-libs/openal )
-	)
-	widgets? (
-		~dev-qt/qtopengl-${PV}
-		~dev-qt/qtwidgets-${PV}[gles2=]
-	)
-"
-DEPEND="${RDEPEND}
-	gstreamer? ( x11-base/xorg-proto )
-"
-
-src_prepare() {
-	sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
-		src/multimedia/multimedia.pro || die
-
-	qt_use_disable_config openal openal \
-		src/imports/imports.pro
-
-	qt_use_disable_mod qml quick \
-		src/src.pro \
-		src/plugins/plugins.pro
-
-	qt_use_disable_mod widgets widgets \
-		src/src.pro \
-		src/gsttools/gsttools.pro \
-		src/plugins/gstreamer/common.pri
-
-	qt5-build_src_prepare
-}
-
-src_configure() {
-	local myqmakeargs=(
-		--
-		$(qt_use alsa)
-		$(qt_use gstreamer)
-		$(qt_use pulseaudio)
-	)
-	qt5-build_src_configure
-}