From: Heather Cynede <cynede@gentoo.org>
Date: Mon, 17 Aug 2015 09:35:51 +0000 (+0400)
Subject: dev-libs/gmime resolve conflict with monolithic gtk-sharp
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=9f1c38128a316f9462f31a876630a5fdc4d392c3;p=gentoo.git

dev-libs/gmime resolve conflict with monolithic gtk-sharp

Package-Manager: portage-2.2.20.1
---

diff --git a/dev-libs/gmime/gmime-2.6.20-r1.ebuild b/dev-libs/gmime/gmime-2.6.20-r1.ebuild
new file mode 100644
index 000000000000..79ad2aaefdf5
--- /dev/null
+++ b/dev-libs/gmime/gmime-2.6.20-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils mono-env gnome2 vala
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME"
+HOMEPAGE="http://spruce.sourceforge.net/gmime/ http://developer.gnome.org/gmime/stable/"
+
+SLOT="2.6"
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc mono static-libs vala"
+
+RDEPEND="
+	>=dev-libs/glib-2.18:2
+	sys-libs/zlib
+	>=app-crypt/gpgme-1.1.6
+	mono? (
+		dev-lang/mono
+		>=dev-dotnet/gtk-sharp-2.12.21:2 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0 )
+"
+
+pkg_setup() {
+	use mono && mono-env_pkg_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-cryptography \
+		--disable-strict-parser \
+		$(use_enable mono) \
+		$(use_enable static-libs static) \
+		$(use_enable vala)
+}
+
+src_compile() {
+	MONO_PATH="${S}" gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	GACUTIL_FLAGS="/root '${ED}/usr/$(get_libdir)' /gacdir '${EPREFIX}/usr/$(get_libdir)' /package ${PN}" \
+		gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc docs/tutorial/html/*
+	fi
+}