From: Marek Szuba <marecki@gentoo.org>
Date: Tue, 11 Jun 2019 13:55:03 +0000 (+0100)
Subject: dev-libs/intel-neo: bump to 19.22.13062 and EAPI-7
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=99a8b1da9299e3e13f0d07f3a116bdf1aa4ecb79;p=gentoo.git

dev-libs/intel-neo: bump to 19.22.13062 and EAPI-7

Signed-off-by: Marek Szuba <marecki@gentoo.org>
Package-Manager: Portage-2.3.66, Repoman-2.3.11
---

diff --git a/dev-libs/intel-neo/Manifest b/dev-libs/intel-neo/Manifest
index a9076df296b6..67d09584a1a1 100644
--- a/dev-libs/intel-neo/Manifest
+++ b/dev-libs/intel-neo/Manifest
@@ -1 +1,2 @@
 DIST intel-neo-19.16.12873.tar.gz 2370395 BLAKE2B 2efc76c9729d3ec000455270e923df1e3d0ec5d0a5c31cd156401b37c63ba01ee2a6051f487a98c4db10f61c2a70434f994f15472f54741ef4a80a71b036636f SHA512 1ec8b7883bfeefc1ed2095eac6111803a44e3c88e8bd1a478fb89a5baa4484fc96894f7ef0c01f4b6b9cb94731cdfc633f38ef2f636fdeb2d5e4344ca4aaa2ae
+DIST intel-neo-19.22.13062.tar.gz 2402939 BLAKE2B e47f19fa602444cb260a2cdd9b676201ec8e4c50fe55c4216f779b8edab3497b5249071edcf5d162457be4f72cd33868cf7a971d99b1ae60e7a5e3714a795e82 SHA512 81ad69d051add3eb8d64373ad2ede0b323a4330c9f18010130e9b3db4d78d6e30e2e37f01c0cb7a77e378af62d9d6dd62755a21b153ae753417a6a2556d61b66
diff --git a/dev-libs/intel-neo/intel-neo-19.22.13062.ebuild b/dev-libs/intel-neo/intel-neo-19.22.13062.ebuild
new file mode 100644
index 000000000000..fa2b3c8393e5
--- /dev/null
+++ b/dev-libs/intel-neo/intel-neo-19.22.13062.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+MY_PN="compute-runtime"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Intel Graphics Compute Runtime for OpenCL, for Gen8 (Broadwell) and beyond"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="vaapi"
+
+BDEPEND="virtual/pkgconfig"
+COMMON="dev-libs/ocl-icd
+	dev-util/intel-graphics-compiler
+	>=media-libs/gmmlib-19.0.0
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		>=x11-libs/libva-2.0.0
+	)"
+DEPEND="${COMMON}
+	media-libs/mesa"	# for Khronos OpenGL headers
+RDEPEND="${COMMON}"
+
+DOCS=(
+	README.md
+	documentation/FAQ.md
+	documentation/LIMITATIONS.md
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-19.16.12873_cmake_no_libva_automagic.patch
+)
+
+S="${WORKDIR}"/${MY_P}
+
+src_configure() {
+	local mycmakeargs=(
+		-DKHRONOS_GL_HEADERS_DIR="${EPREFIX}/usr/include"
+		-DENABLE_VAAPI_MEDIA_SHARING=$(usex vaapi "ON" "OFF")
+		# If enabled, tests are automatically run during the compile phase
+		# - and we cannot run them because they require permissions to access
+		# the hardware.
+		-DSKIP_UNIT_TESTS=ON
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	"${ROOT}"/usr/bin/eselect opencl set --use-old ocl-icd
+}