From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 5 May 2019 06:54:50 +0000 (+0200)
Subject: dev-python/qtconsole: Drop py2
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=98a35ce7c2b7ac8f2eafad0702f68317cd3babc9;p=gentoo.git

dev-python/qtconsole: Drop py2

Closes: https://bugs.gentoo.org/684962
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---

diff --git a/dev-python/qtconsole/qtconsole-4.3.1-r1.ebuild b/dev-python/qtconsole/qtconsole-4.3.1-r1.ebuild
new file mode 100644
index 000000000000..9739aa4e8f2f
--- /dev/null
+++ b/dev-python/qtconsole/qtconsole-4.3.1-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Qt-based console for Jupyter with support for rich media output"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-4.1.1[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		>=dev-python/ipython-4.0.0-r2[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.3.1-r1[${PYTHON_USEDEP}]
+	)
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' 'python2*')
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+		dev-python/PyQt5[${PYTHON_USEDEP},svg,testlib]
+	)
+	dev-python/PyQt5[${PYTHON_USEDEP},svg]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-13[${PYTHON_USEDEP}]
+	"
+PDEPEND="dev-python/ipython[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	# jupyter qtconsole --generate-config ... jupyter-qtconsole: cannot connect to X server
+	# ERROR
+	sed \
+		-e 's:test_generate_config:_&:g' \
+		-i qtconsole/tests/test_app.py || die
+	virtx nosetests --verbosity=2 qtconsole
+}