From: Patrick McLean <chutzpah@gentoo.org>
Date: Sat, 7 Dec 2019 21:47:37 +0000 (-0800)
Subject: dev-python/flit: New package
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=92773d426b2d6b6f1bea832cdbf6709d03f40e07;p=gentoo.git

dev-python/flit: New package

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---

diff --git a/dev-python/flit/Manifest b/dev-python/flit/Manifest
new file mode 100644
index 000000000000..98fa24ff4f58
--- /dev/null
+++ b/dev-python/flit/Manifest
@@ -0,0 +1 @@
+DIST flit-2.1.0.tar.gz 106459 BLAKE2B db51d8cc119ae8aa5f8d0ac1655cd29390065567391cbdf06ca7dbb98a79e96a6d8f318273c2f9a58aaf549090a903360701a844ac071d15304a21ea54052a91 SHA512 0fcbfaa1e5e83216a5c98cc87b0a8f2aa17e2c184ec3f09c7dd0dd5e695311be62344ac4f101cb71f87390513496f8c1152a2cd8d7363202f7696ee002f07a55
diff --git a/dev-python/flit/files/flit-2.1.0-tests.patch b/dev-python/flit/files/flit-2.1.0-tests.patch
new file mode 100644
index 000000000000..04cf9839dbc4
--- /dev/null
+++ b/dev-python/flit/files/flit-2.1.0-tests.patch
@@ -0,0 +1,8 @@
+diff --git a/tests/test_inifile.py b/tests/test_inifile.py
+index 150fa47..53ce597 100644
+--- a/tests/test_inifile.py
++++ b/tests/test_inifile.py
+@@ -7,2 +7,3 @@ samples_dir = Path(__file__).parent / 'samples'
+ 
++@pytest.mark.skip("Needs internet access")
+ def test_invalid_classifier():
diff --git a/dev-python/flit/flit-2.1.0.ebuild b/dev-python/flit/flit-2.1.0.ebuild
new file mode 100644
index 000000000000..ea8427af6c24
--- /dev/null
+++ b/dev-python/flit/flit-2.1.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Simplified packaging of Python modules"
+HOMEPAGE="https://github.com/takluyver/flit https://flit.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/flit_core[${PYTHON_USEDEP}]
+	dev-python/intreehooks[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests_download[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	sys-apps/grep
+	sys-apps/findutils
+	test? (
+		>=dev-python/pytest-2.7.3[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/flit-2.1.0-tests.patch"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/pygments-github-lexers \
+
+python_prepare_all() {
+	printf -- "from setuptools import setup, find_packages\nsetup(name='%s',version='%s',%s)" \
+		"${PN}" "${PV}" "packages=find_packages(exclude=['tests'])" > setup.py || die
+
+	# use toml instead of depricated pytoml
+	grep -r -l -Z -F 'pytoml' | xargs -0 \
+		sed -e 's:import pytoml as toml:import toml:' \
+			-e 's:pytoml:toml:' -i || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/flit/metadata.xml b/dev-python/flit/metadata.xml
new file mode 100644
index 000000000000..48a322e099ad
--- /dev/null
+++ b/dev-python/flit/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>chutzpah@gentoo.org</email>
+    <name>Patrick McLean</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">flit</remote-id>
+    <remote-id type="github">takluyver/flit</remote-id>
+  </upstream>
+</pkgmetadata>