From: Guillaume Seren <guillaumeseren@gmail.com>
Date: Sun, 23 Jun 2019 14:31:18 +0000 (+0200)
Subject: dev-python/urwidtrees: Add python3_7 + EAPI7
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=8e9679eaa043e23257e1a784c2be5a187cf46351;p=gentoo.git

dev-python/urwidtrees: Add python3_7 + EAPI7

Signed-off-by: Guillaume Seren <guillaumeseren@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/11515
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---

diff --git a/dev-python/urwidtrees/urwidtrees-1.0.2-r1.ebuild b/dev-python/urwidtrees/urwidtrees-1.0.2-r1.ebuild
new file mode 100644
index 000000000000..57257e1b3565
--- /dev/null
+++ b/dev-python/urwidtrees/urwidtrees-1.0.2-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Tree widgets for urwid"
+HOMEPAGE="https://github.com/pazz/urwidtrees"
+SRC_URI="https://github.com/pazz/urwidtrees/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+RDEPEND=">=dev-python/urwid-1.1.0[${PYTHON_USEDEP}]"
+
+src_prepare() {
+	find -name '*.py' -exec \
+		sed -i -e '1i# -*- coding: utf-8 -*-' {} + || die
+
+	distutils-r1_src_prepare
+
+	local md
+	for md in *.md; do
+		mv "${md}" "${md%.md}" || die
+	done
+}
+
+src_compile() {
+	distutils-r1_src_compile
+
+	use doc && emake -C docs html
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	if use doc; then
+		dodoc -r docs/build/html/.
+	fi
+}