From: David Seifert <soap@gentoo.org>
Date: Fri, 13 Dec 2019 17:40:26 +0000 (+0100)
Subject: sci-libs/gaul-devel: Port to EAPI 7
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=8bd7dae129172172c2e57aa497c26466767e4f46;p=gentoo.git

sci-libs/gaul-devel: Port to EAPI 7

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: David Seifert <soap@gentoo.org>
---

diff --git a/sci-libs/gaul-devel/gaul-devel-0.1849-r2.ebuild b/sci-libs/gaul-devel/gaul-devel-0.1849-r2.ebuild
index 56d910c69c5a..883d578b3fea 100644
--- a/sci-libs/gaul-devel/gaul-devel-0.1849-r2.ebuild
+++ b/sci-libs/gaul-devel/gaul-devel-0.1849-r2.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=7
 
-inherit autotools eutils
+inherit autotools
 
 DESCRIPTION="Genetic Algorithm Utility Library"
 HOMEPAGE="http://GAUL.sourceforge.net/"
@@ -12,34 +12,33 @@ SRC_URI="mirror://sourceforge/gaul/${P}-0.tar.bz2"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="debug slang static-libs"
+IUSE="slang"
 
-DEPEND="
-	sys-apps/sed
-	slang? ( sys-libs/slang )"
-RDEPEND="${DEPEND}"
+RDEPEND="slang? ( sys-libs/slang:= )"
+DEPEND="${RDEPEND}"
 
-S=${WORKDIR}/${P}-0
+S="${WORKDIR}/${P}-0"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-slang2-error.patch
+	"${FILESDIR}"/${P}-as-needed.patch
+)
 
 src_prepare() {
-	epatch \
-		"${FILESDIR}"/${P}-slang2-error.patch \
-		"${FILESDIR}"/${P}-as-needed.patch
+	default
+	mv configure.{in,ac} || die
 	eautoreconf
 }
 
 src_configure() {
-	local myconf
-	use slang || myconf="--enable-slang=no"
-	if use debug ; then
-		myconf="${myconf} --enable-debug=yes --enable-memory-debug=yes"
-	else
-		myconf="${myconf} --enable-g=no"
-	fi
-	econf $(use_enable static-libs static) ${myconf}
+	econf \
+		--disable-static \
+		$(use_enable slang)
 }
 
 src_install() {
-	MAKEOPTS+=" -j1"
 	default
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
 }