From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Sat, 21 Mar 2020 10:59:14 +0000 (+0000)
Subject: app-emulation/ski: add USE=debug to make binutils-libs opetional
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=8567efbb44f58538cefc84aeeac9ea2adc904fd5;p=gentoo.git

app-emulation/ski: add USE=debug to make binutils-libs opetional

ski's needs runtime detection of sys-libs/binutils-libs features
which is not compatible with cross-compilation. Let's make the
feature optional.

Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---

diff --git a/app-emulation/ski/metadata.xml b/app-emulation/ski/metadata.xml
index 36a9f93ec0bb..b37238378ea2 100644
--- a/app-emulation/ski/metadata.xml
+++ b/app-emulation/ski/metadata.xml
@@ -9,6 +9,9 @@
 		<email>ia64@gentoo.org</email>
 		<name>Gentoo Linux IA-64 Development</name>
 	</maintainer>
+	<use>
+		<flag name='debug'>enable extra binary emulation debugging via <pkg>sys-libs/binutils-libs</pkg></flag>
+	</use>
 	<upstream>
 		<remote-id type="sourceforge">ski</remote-id>
 	</upstream>
diff --git a/app-emulation/ski/ski-1.3.2-r4.ebuild b/app-emulation/ski/ski-1.3.2-r4.ebuild
new file mode 100644
index 000000000000..3d904abf6d44
--- /dev/null
+++ b/app-emulation/ski/ski-1.3.2-r4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="ia64 instruction set simulator"
+HOMEPAGE="http://ski.sourceforge.net/ http://www.gelato.unsw.edu.au/IA64wiki/SkiSimulator"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug motif"
+
+RDEPEND="dev-libs/libltdl:0=
+	sys-libs/ncurses:0=
+	virtual/libelf
+	debug? ( sys-libs/binutils-libs:0= )
+	motif? ( x11-libs/motif:0= )"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex
+	dev-util/gperf"
+
+# games-sports/ski and app-emulation/ski both install 'ski' binary, bug #653110
+RDEPEND="${RDEPEND} !!games-sports/ski"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-syscall-linux-includes.patch
+	"${FILESDIR}"/${P}-remove-hayes.patch
+	"${FILESDIR}"/${P}-no-local-ltdl.patch
+	"${FILESDIR}"/${P}-AC_C_BIGENDIAN.patch
+	"${FILESDIR}"/${P}-configure-withval.patch
+	"${FILESDIR}"/${P}-binutils.patch
+	"${FILESDIR}"/${P}-uselib.patch #592226
+	"${FILESDIR}"/${P}-ncurses-config.patch
+	"${FILESDIR}"/${P}-prototypes.patch
+	"${FILESDIR}"/${P}-glibc-2.28.patch
+	"${FILESDIR}"/${P}-gcc-10.patch #707144
+)
+
+src_prepare() {
+	default
+
+	if has_version ">=sys-libs/binutils-libs-2.34"; then
+		eapply "${FILESDIR}"/${PN}-1.3.2-binutils-2.34.patch
+	fi
+
+	rm -rf libltdl src/ltdl.[ch] macros/ltdl.m4
+
+	AT_M4DIR="macros" eautoreconf
+}
+
+src_configure() {
+	econf \
+		--without-included-ltdl \
+		--without-gtk \
+		$(use_with motif x11) \
+		$(use_with debug bfd)
+}