From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 9 Nov 2019 21:31:02 +0000 (+0100)
Subject: dev-java/wsdl4j: Bump to EAPI 7
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=82d5d6f2f5463d3f612e62f9321333532ad8339e;p=gentoo.git

dev-java/wsdl4j: Bump to EAPI 7

Closes: https://bugs.gentoo.org/697358
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---

diff --git a/dev-java/wsdl4j/wsdl4j-1.6.2.ebuild b/dev-java/wsdl4j/wsdl4j-1.6.2.ebuild
index 0c4ab5f3f3c5..671b3781782a 100644
--- a/dev-java/wsdl4j/wsdl4j-1.6.2.ebuild
+++ b/dev-java/wsdl4j/wsdl4j-1.6.2.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
 JAVA_PKG_IUSE="doc source test"
 
-inherit versionator java-pkg-2 java-ant-2
+inherit java-pkg-2 java-ant-2
 
 DESCRIPTION="Web Services Description Language for Java Toolkit (WSDL4J)"
 HOMEPAGE="http://wsdl4j.sourceforge.net"
@@ -19,35 +19,37 @@ SRC_URI="mirror://sourceforge/${PN}/${PN}-src-${PV}.zip
 LICENSE="CPL-1.0"
 SLOT="0"
 KEYWORDS="amd64 ~ppc64 x86"
+# tests fail with encoding errors
+RESTRICT="test"
 
 DEPEND=">=virtual/jdk-1.4
-	test? ( =dev-java/junit-3.8* )
+	test? ( dev-java/junit:0 )
 	app-arch/unzip"
 RDEPEND=">=virtual/jre-1.4"
 
-S="${WORKDIR}/${PN}-$(replace_all_version_separators _)"
-TCK_S="${WORKDIR}/${TCK}-$(replace_all_version_separators _ ${TCK_V})"
+S="${WORKDIR}/${P//./_}"
+TCK_S="${WORKDIR}/${TCK}-${TCK_V//./_}"
 
-src_unpack() {
-	unpack ${A}
+EANT_BUILD_TARGET="compile"
+EANT_DOC_TARGET="javadocs"
+
+src_prepare() {
+	default
 	if use test; then
 		rm -v "${TCK_S}"/lib/*.jar || die
-		epatch "${FILESDIR}/1.6.2-tests-sandbox.patch"
+		eapply "${FILESDIR}/1.6.2-tests-sandbox.patch"
 	fi
 }
 
-EANT_BUILD_TARGET="compile"
-EANT_DOC_TARGET="javadocs"
-
 src_test() {
-	ln -s "${TCK_S}" test
-	cd "${TCK_S}"
+	ln -s "${TCK_S}" test || die
+	cd "${TCK_S}" || die
 	java-ant_rewrite-classpath
 	local junit="$(java-pkg_getjars junit)"
 	eant -Dbuild.lib="${S}/test/lib" compile \
 		-Dgentoo.classpath="${S}/build/lib/${PN}.jar:${junit}"
-	cd "${S}"
-	mkdir "${T}/lib"
+	cd "${S}" || die
+	mkdir "${T}/lib" || die
 	ANT_TASKS="ant-junit" eant test -Dtemp.dir="${T}"
 }