From: Miroslav Šulc <fordfrog@gentoo.org>
Date: Fri, 13 Dec 2019 10:59:46 +0000 (+0100)
Subject: media-libs/libgig-9999: added live ebuild
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=7f18041201c07add5cfff5007a64ba632dc10912;p=gentoo.git

media-libs/libgig-9999: added live ebuild

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
---

diff --git a/media-libs/libgig/libgig-9999.ebuild b/media-libs/libgig/libgig-9999.ebuild
new file mode 100644
index 000000000000..561d6f46afc3
--- /dev/null
+++ b/media-libs/libgig/libgig-9999.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools subversion
+
+DESCRIPTION="C++ library for loading Gigasampler and DLS level 1/2 files"
+HOMEPAGE="https://www.linuxsampler.org/libgig/"
+ESVN_REPO_URI="https://svn.linuxsampler.org/svn/libgig/trunk"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc"
+
+RDEPEND="
+	media-libs/audiofile
+	media-libs/libsndfile"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+
+	emake -f Makefile.svn
+	eautoreconf
+}
+
+src_compile() {
+	emake
+	use doc && emake docs
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	use doc && HTML_DOCS=( doc/html/. )
+	einstalldocs
+
+	# For libgig.so to be found at runtime
+	printf "LDPATH=\"${EPREFIX}/usr/$(get_libdir)/libgig/\"" > 99${PN}
+	doenvd "99${PN}"
+}