From: Jeroen Roovers <jer@gentoo.org>
Date: Mon, 20 Apr 2020 14:29:40 +0000 (+0200)
Subject: www-client/opera-developer: Version 69.0.3665.0
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=7ee8e2e6fa79d494a724fb1889f2faf47ecccb25;p=gentoo.git

www-client/opera-developer: Version 69.0.3665.0

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index bfa0bef9fd2c..3ddcf1fbfaeb 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,2 +1,3 @@
 DIST opera-developer_69.0.3653.0_amd64.deb 66162840 BLAKE2B 00c3b8b1069dc83067e7f380b19241515eb13af9b847caa077867dd0fa05a927886a2281e875098eb01c7121de33b9296083565df4931e186856da1bae77a02a SHA512 c27b3e4667a00e288ac4e30dd035b2ffbf7ac269de7d535402af73517662b31a807d0b4b43bdc7d21384750df92443dc5933223478d6453bb7af57b9b37b745d
 DIST opera-developer_69.0.3660.0_amd64.deb 66332904 BLAKE2B 9a92545c226de0c0a40e9d04590efeb494d0885bec9c7324a2a7531daad4b7c643b1200f9efee21d8cc6358b1416feda2d7e109bf1f367a59b2a55e81d75c6d2 SHA512 60be272c5bf31940ef9fe928f1530a6fa922b95c510a6f540a99a1c11c6ffaf6ef385c0488cda3821a814517182bbda382e9a8584910c9bcc6360c8613b8333b
+DIST opera-developer_69.0.3665.0_amd64.deb 66148548 BLAKE2B 8f8ad5c9b034b573c297fb86beb959a9fe5c2bc8f71383f27796c21a95463c9839c7e32973b9003c8ac210be51072fa2ec227e7262db121759af3fd6c1d49bd1 SHA512 ab7953c09c6e1d13ec12ffe65a4b5b0810b16e08eb00012e8ffdb2b512b6c02baefdb5b8d70f0251ee9cf6680e6dd21e5ea73490b3f7f1e1a8b89738fd5dccf6
diff --git a/www-client/opera-developer/opera-developer-69.0.3665.0.ebuild b/www-client/opera-developer/opera-developer-69.0.3665.0.ebuild
new file mode 100644
index 000000000000..837674712eae
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-69.0.3665.0.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	rm usr/bin/${PN} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}