From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 10 Nov 2019 11:05:10 +0000 (+0100)
Subject: media-sound/protux: Bump to EAPI 7
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=67b0ab998de076dd447c0f2f66b37379212e0961;p=gentoo.git

media-sound/protux: Bump to EAPI 7

Closes: https://bugs.gentoo.org/697266
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---

diff --git a/media-sound/protux/protux-0.50.100.ebuild b/media-sound/protux/protux-0.50.100.ebuild
index 3b8777e18cbb..f4f130c2bd87 100644
--- a/media-sound/protux/protux-0.50.100.ebuild
+++ b/media-sound/protux/protux-0.50.100.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
 inherit java-pkg-2
 
@@ -9,37 +9,38 @@ DESCRIPTION="Professional Audio Tools for GNU/Linux"
 HOMEPAGE="http://protux.sourceforge.net/"
 SRC_URI="http://${PN}.sourceforge.net/releases/${P}.tar.gz"
 
-IUSE="source"
-SLOT="0"
 LICENSE="GPL-2"
+SLOT="0"
 KEYWORDS="~amd64 x86"
+IUSE="source"
 
 DEPEND=">=virtual/jdk-1.5
 	source? ( app-arch/zip )"
 
 S="${WORKDIR}/${PN}"
 
-src_unpack() {
-	unpack ${A}
+src_prepare() {
+	default
 
 	# bug #318589
-	sed -i '/com.sun.jmx.snmp.Enumerated/d' "${S}/src/org/protux/core/GlobalProperties.java" || die
+	sed -i '/com.sun.jmx.snmp.Enumerated/d' \
+		src/org/protux/core/GlobalProperties.java || die
 }
 
 src_compile() {
-	cd src
+	cd src || die
 	ejavac -encoding latin1 $(find . -name "*.java")
 	jar cf ${PN}.jar $(find . -name "*.class") || die
 }
 
 src_install() {
 	java-pkg_dojar src/${PN}.jar
-	dodoc AUTHORS BUGLIST ChangeLog COPYRIGHT INSTALL README TODO || die
+	dodoc AUTHORS BUGLIST ChangeLog COPYRIGHT INSTALL README TODO
 	use source && java-pkg_dosrc src/org
 	# pwd like this because it does not find resources otherwise
 	java-pkg_dolauncher ${PN} \
 		--main org.protux.Main \
 		--pwd /usr/share/${PN}
 	insinto /usr/share/${PN}
-	doins -r resources || die
+	doins -r resources
 }