From: Matthew Thode <prometheanfire@gentoo.org>
Date: Tue, 9 Apr 2019 03:35:24 +0000 (-0500)
Subject: dev-python/pycadf: 2.9.0 bump
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=6490e43425c62afaa9e16f660e832ce503516f8b;p=gentoo.git

dev-python/pycadf: 2.9.0 bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>
---

diff --git a/dev-python/pycadf/Manifest b/dev-python/pycadf/Manifest
index 612d0d5869f2..9b28a1e37ef4 100644
--- a/dev-python/pycadf/Manifest
+++ b/dev-python/pycadf/Manifest
@@ -1,2 +1,3 @@
 DIST pycadf-2.6.0.tar.gz 249411 BLAKE2B 7ddbbcb9355502910ba023589181cbf2d6a104454ca408b604eee031ce79c547213961d10bec4d891e8ddfb00ccacaf1dff1f5bb2646913e9c0bb79abfd4ae72 SHA512 a581b54a8dae088e015d639f14eb46b3c41bdbfdd55b671e79f34b7392af49e3e8dbb2fd85a43e5f8e010cbcdba1d9a330972b5cb6f7f2c5179c00b6f135b4ec
 DIST pycadf-2.7.0.tar.gz 248233 BLAKE2B b2258e0f2027811c35cfcf7063821bd41cc83291d5ace7969fcd48d2e76b4f1a24e8a09b60f996f2edc7e9c37c1578cda40bd2bbd0a1ecbfc889a1d9bbab6ca4 SHA512 093c633c82345154c45c7b8b3dd38ef8101fc6a6aa980a44fc69887409a8facd987a960f403150401a64f2186113bdf5e8c05a3996f3ca4c55f9dc40ab8bfa8d
+DIST pycadf-2.9.0.tar.gz 249992 BLAKE2B d6c1fd12991e24fa747e2f0ba35719faf6b4392334957ead977901f14c8cd98b26f1f93e4b866085e73b7009f66a1ce692e58e478ec501dd4fa988ebf11c2f5b SHA512 da94d778db2fa06b129ae5e85151e301eb68b9ca551fe33f86a9e627cf2c879c71451df140dddbc6d3dfcbac4b6939fce6748711549400713e96165b6673c356
diff --git a/dev-python/pycadf/pycadf-2.9.0.ebuild b/dev-python/pycadf/pycadf-2.9.0.ebuild
new file mode 100644
index 000000000000..279904ccfdfc
--- /dev/null
+++ b/dev-python/pycadf/pycadf-2.9.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="python implementation of DMTF Cloud Audit (CADF) data model"
+HOMEPAGE="https://pypi.org/project/pycadf/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-1.8.0[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/coverage-4.0[${PYTHON_USEDEP}]
+		!~dev-python/coverage-4.4[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/stestr-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-4.7.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/openstackdocstheme-1.18.1[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.6.6[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.6.7[${PYTHON_USEDEP}]
+	)"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-2.18.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && "${PYTHON}" setup.py build_sphinx
+}
+
+python_test() {
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}