From: James Le Cuirot <chewi@gentoo.org>
Date: Fri, 25 Sep 2015 23:00:32 +0000 (+0100)
Subject: dev-java/wstx: Bump Java version to 6 and remove tons of unneeded deps
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=5dbef55facbeb1d4b20f1e56e111881e18dddd22;p=gentoo.git

dev-java/wstx: Bump Java version to 6 and remove tons of unneeded deps

emma and xsdlib just plain aren't needed. stax and jaxp-virtual are
included in Java 6. ant-nodeps and ant-trax are dummy packages. We
should depend on ant-junit, not junit.

Also update the homepage as Codehaus is dead. This old version is
practically nowhere to be found except our mirrors.

Package-Manager: portage-2.2.20.1
---

diff --git a/dev-java/wstx/wstx-3.2.9-r1.ebuild b/dev-java/wstx/wstx-3.2.9-r1.ebuild
new file mode 100644
index 000000000000..3cce75cb59f3
--- /dev/null
+++ b/dev-java/wstx/wstx-3.2.9-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Woodstox is a high-performance validating namespace-aware XML-processor"
+HOMEPAGE="https://github.com/FasterXML/woodstox"
+SRC_URI="mirror://gentoo/${PN}-src-${PV}.zip"
+LICENSE="Apache-2.0"
+SLOT="3.2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+
+CDEPEND="dev-java/sax:0
+	dev-java/msv:0
+	dev-java/relaxng-datatype:0"
+
+RDEPEND="${CDEPEND}
+	>=virtual/jre-1.6"
+
+DEPEND="${CDEPEND}
+	>=virtual/jdk-1.6
+	app-arch/unzip
+	test? ( dev-java/ant-junit:0 )"
+
+EANT_BUILD_TARGET="jars"
+EANT_DOC_TARGET="javadoc"
+
+# Don't need to make a folder
+S="${WORKDIR}"
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+
+java_prepare() {
+	rm -v lib/msv/*.jar || die
+	rm -v lib/*.jar || die
+
+	# Get rid of a missing include.
+	epatch "${FILESDIR}"/${P}-build.xml.patch
+}
+
+EANT_GENTOO_CLASSPATH="sax,msv,relaxng-datatype"
+
+src_test(){
+	java-pkg-2_src_test
+}
+
+src_install() {
+	java-pkg_newjar build/"${PN}"-api-"${PV}".jar "${PN}"-api.jar
+	java-pkg_newjar build/"${PN}"-asl-"${PV}".jar "${PN}".jar
+	use doc && java-pkg_dojavadoc build/javadoc
+	use source && java-pkg_dosrc src
+}