From: Sebastian Pipping <sping@gentoo.org>
Date: Sat, 7 Mar 2020 17:28:59 +0000 (+0100)
Subject: dev-python/blessings: Python 3.8 + QA fixes
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=5daf1ff49aeb0df600d3c7baaeccb548a081615c;p=gentoo.git

dev-python/blessings: Python 3.8 + QA fixes

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.92, Repoman-2.3.20
---

diff --git a/dev-python/blessings/blessings-1.7-r1.ebuild b/dev-python/blessings/blessings-1.7-r1.ebuild
new file mode 100644
index 000000000000..4d4244fee145
--- /dev/null
+++ b/dev-python/blessings/blessings-1.7-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="A thin, practical wrapper around terminal coloring, styling, and positioning"
+HOMEPAGE="https://github.com/erikrose/blessings https://pypi.org/project/blessings/"
+# https://github.com/erikrose/blessings/pull/136
+SRC_URI="https://github.com/erikrose/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs/ docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# The tests need an interactive terminal
+	# https://github.com/erikrose/blessings/issues/117
+	script -eqc "nosetests -v -w \"${BUILD_DIR}\"" /dev/null \
+		|| die "tests failed with ${EPYTHON}"
+}