From: Mart Raudsepp <leio@gentoo.org>
Date: Sun, 15 Mar 2020 17:02:43 +0000 (+0200)
Subject: gnome-base/gnome-settings-daemon: bump to 3.34.2
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=5418a0a8b2052ff26980142b80c26e827dd55f89;p=gentoo.git

gnome-base/gnome-settings-daemon: bump to 3.34.2

Closes: https://bugs.gentoo.org/712448
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---

diff --git a/gnome-base/gnome-settings-daemon/Manifest b/gnome-base/gnome-settings-daemon/Manifest
index 3cd582557836..f3de767e785a 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -1,2 +1,4 @@
 DIST gnome-settings-daemon-3.32.1-patchset.tar.xz 9840 BLAKE2B 0b0249b6335fc64c111cfd4c221b408460105bd544527ca29a32b2ceb82d39c1ca8c9813916cde9afdac1cf146c1286ed937dadb07eb0263b5ab3ada2a95e0aa SHA512 175f4d0200b88b696b73fc7e7b10065b3e6f046e48955408cc438499fdc6464483420b4801dbb77b5ae819cb52a131e2594a628b9731eaa167b802b5b2cbe855
 DIST gnome-settings-daemon-3.32.1.tar.xz 1372968 BLAKE2B ba0596d9f2019f2ecff32b70c03d962dd7966c282d1fb0ea94c38fc895b7ef788d9dd179a037b74a319ca520811e985465578a725bf14d1eff92846f188445ea SHA512 8d6aca1041cbd50d7dda67dc711269a51c4a5148d55dc63969f47c21bf309126f5d5cb13c1e6fa9e6498fbb30dc70fa7a049fead7d32c6a20d550da0ce8828c3
+DIST gnome-settings-daemon-3.34.2-patchset.tar.xz 23824 BLAKE2B ce2b0720f340353ce9a27f81ac5b7a17ae44234596d80a183fe9dc69a6dd49c6b750a816b75c43df357436b32a74f48358602615c9b134cd12cd1d0d960ea2d1 SHA512 ba10afe2cd28592501c47b2eba8473a4a08d927a1fd292f738a2ae16df73e64a97e4520a680ace93c81755a60d9c378792d47b4028d1dbd3b0ff6514d5210f3d
+DIST gnome-settings-daemon-3.34.2.tar.xz 1397504 BLAKE2B a96728068a395892b67aa4b5f3223aa96d2f0d431d1836136483a5344ee2a490d2ad5a1978c265bc6d652ec3863b71f055405681fe0b2466b1a3bfd146712c4a SHA512 c5fab3af6d37dfb4dd9deff0656965699bb6c07f010c5040bb15b2fe5f7810b4815007975ad7a9841899ae1735273e394bb9539f32ab0464875cbb3648234f37
diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.34.2.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.34.2.ebuild
new file mode 100644
index 000000000000..8a714c6cdb70
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.34.2.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{3_6,3_7} )
+
+inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+colord +cups debug elogind input_devices_wacom modemmanager networkmanager smartcard systemd test +udev wayland"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+	input_devices_wacom? ( udev )
+	wayland? ( udev )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+DEPEND="
+	>=sci-geosciences/geocode-glib-3.10
+	>=dev-libs/glib-2.56:2
+	>=gnome-base/gnome-desktop-3.34.2:3=
+	>=gnome-base/gsettings-desktop-schemas-3.33.0
+	>=x11-libs/gtk+-3.15.3:3[X,wayland?]
+	>=dev-libs/libgweather-3.9.5:2=
+	colord? (
+		>=x11-misc/colord-1.3.5:=
+		>=media-libs/lcms-2.2:2 )
+	media-libs/libcanberra[gtk3]
+	>=app-misc/geoclue-2.3.1:2.0
+	>=x11-libs/libnotify-0.7.3
+	>=media-sound/pulseaudio-2[glib]
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99.8:=
+	x11-libs/libX11
+	udev? ( dev-libs/libgudev:= )
+	wayland? ( dev-libs/wayland )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.7
+		>=x11-libs/pango-1.20.0
+		x11-libs/gdk-pixbuf:2 )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	cups? ( >=net-print/cups-1.4[dbus] )
+	modemmanager? ( >=app-crypt/gcr-3.7.5:=
+		>=net-misc/modemmanager-1.0:= )
+	networkmanager? ( >=net-misc/networkmanager-1.0 )
+	media-libs/alsa-lib
+	x11-libs/libXi
+	x11-libs/libXext
+	media-libs/fontconfig
+	systemd? ( sys-apps/systemd
+		sys-apps/dbus[user-session] )
+"
+# logind needed for power and session management, bug #464944
+# gnome-session-3.33.90/gdm-3.33.90/gnome-shell-extensions-3.34.1/gnome-flashback-3.33.1 adapt to Clipboard and Mouse component removals (moved to mutter)
+RDEPEND="${DEPEND}
+	gnome-base/dconf
+	elogind? ( sys-auth/elogind )
+	!<gnome-base/gnome-session-3.33.90
+	!<gnome-base/gdm-3.33.90
+	!<gnome-extra/gnome-shell-extensions-3.34.1
+	!<gnome-base/gnome-flashback-3.33.1
+"
+# rfkill requires linux/rfkill.h (and USE=udev), thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead
+BDEPEND="
+	sys-kernel/linux-headers
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	x11-base/xorg-proto
+	${PYTHON_DEPS}
+	test? (
+		$(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+		$(python_gen_any_dep 'dev-python/dbusmock[${PYTHON_USEDEP}]')
+		gnome-base/gnome-session )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Translation update from gnome-3-34 branch
+	# Allow disabling udev and networkmanager on Linux
+	# Make colord and wacom optional
+	"${WORKDIR}"/patches/
+	"${FILESDIR}"/3.32.1-fix-wacom-no-wayland.patch #677494, fixed in 3.36
+)
+
+python_check_deps() {
+	if use test; then
+		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+		has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		#-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss?
+		-Dudev_dir="$(get_udevdir)"
+		$(meson_use systemd)
+		-Dalsa=true
+		$(meson_use udev gudev)
+		$(meson_use colord)
+		$(meson_use cups)
+		$(meson_use networkmanager network_manager)
+		$(meson_use udev rfkill)
+		$(meson_use smartcard)
+		$(meson_use input_devices_wacom wacom)
+		$(meson_use wayland)
+		$(meson_use modemmanager wwan)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	# Don't auto-suspend by default on AC power
+	insinto /usr/share/glib-2.0/schemas
+	doins "${FILESDIR}"/org.gnome.settings-daemon.plugins.power.gschema.override
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/gnome-base/gnome-settings-daemon/metadata.xml b/gnome-base/gnome-settings-daemon/metadata.xml
index b5c446621532..56e10206e072 100644
--- a/gnome-base/gnome-settings-daemon/metadata.xml
+++ b/gnome-base/gnome-settings-daemon/metadata.xml
@@ -7,6 +7,7 @@
 	</maintainer>
 	<use>
 		<flag name="elogind">Rely on <pkg>sys-auth/elogind</pkg> as runtime logind provider</flag>
+		<flag name="modemmanager">Enable WWAN support via <pkg>net-misc/modemmanager</pkg></flag>
 		<flag name="systemd">Rely on <pkg>sys-apps/systemd</pkg> as runtime logind provider</flag>
 	</use>
 </pkgmetadata>