From: Jeroen Roovers <jer@gentoo.org>
Date: Sun, 19 Apr 2020 09:19:30 +0000 (+0200)
Subject: net-analyzer/ike-scan: Add live ebuild
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=4143943a909e4ef0a97d1253c11233b49ffc824c;p=gentoo.git

net-analyzer/ike-scan: Add live ebuild

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---

diff --git a/net-analyzer/ike-scan/ike-scan-99999.ebuild b/net-analyzer/ike-scan/ike-scan-99999.ebuild
new file mode 100644
index 000000000000..1e9a5ce43bb9
--- /dev/null
+++ b/net-analyzer/ike-scan/ike-scan-99999.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3
+
+DESCRIPTION="A utility for finding, fingerprinting and testing IKE VPN servers"
+HOMEPAGE="https://github.com/royhills/ike-scan/"
+EGIT_REPO_URI="https://github.com/royhills/ike-scan"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="libressl ssl"
+KEYWORDS=""
+
+DEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+
+src_prepare() {
+	# Fix buffer overflow, bug #277556
+	sed \
+		-e "/MAXLINE/s:255:511:g" \
+		-i ike-scan.h || die
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with ssl openssl)
+}
+
+src_install() {
+	default
+	dodoc udp-backoff-fingerprinting-paper.txt
+}