From: Julian Ospald <hasufell@gentoo.org>
Date: Sun, 4 Oct 2015 20:07:59 +0000 (+0200)
Subject: media-libs/liblrdf: add libressl support
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=3f5f773c4ad5b5e6c6701619366d6dd933db1b7d;p=gentoo.git

media-libs/liblrdf: add libressl support
---

diff --git a/media-libs/liblrdf/liblrdf-0.5.0-r1.ebuild b/media-libs/liblrdf/liblrdf-0.5.0-r1.ebuild
new file mode 100644
index 000000000000..1758259c338c
--- /dev/null
+++ b/media-libs/liblrdf/liblrdf-0.5.0-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools
+
+DESCRIPTION="A library for the manipulation of RDF file in LADSPA plugins"
+HOMEPAGE="https://github.com/swh/LRDF"
+SRC_URI="https://github.com/swh/LRDF/tarball/${PV} -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="libressl static-libs"
+
+RDEPEND="
+	!libressl? ( >=dev-libs/openssl-1:0 )
+	libressl? ( dev-libs/libressl )
+	media-libs/raptor:2
+	>=media-libs/ladspa-sdk-1.12"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_unpack() {
+	unpack ${A}
+	mv *-LRDF-* "${S}"
+}
+
+src_prepare() {
+	sed -i -e 's:usr/local:usr:' examples/{instances,remove}_test.c || die #392221
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_test() {
+	has_version media-plugins/swh-plugins && default #392221
+}
+
+src_install() {
+	default
+	rm -f "${ED}"usr/lib*/liblrdf.la
+}