From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Wed, 16 Oct 2019 21:39:27 +0000 (+0200)
Subject: net-misc/rdesktop: 1.9.0 bump
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=33ec8241c7b2e85c0ea2b96d560b7b8ba2350ca0;p=gentoo.git

net-misc/rdesktop: 1.9.0 bump

Many changes, including:
* Use GnuTLS and nettle instead of OpenSSL
* Improved certificate handling
* Add support for dynamic resize of sessions
* Add PulseAudio support

Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---

diff --git a/net-misc/rdesktop/Manifest b/net-misc/rdesktop/Manifest
index e521b8ca528f..fd6f2357f094 100644
--- a/net-misc/rdesktop/Manifest
+++ b/net-misc/rdesktop/Manifest
@@ -1 +1,2 @@
 DIST rdesktop-1.8.6.tar.gz 321061 BLAKE2B bd61ecfbdca3f05b2a8d7f84c10296af3845870f5bd2522ecd768ce27cdbf790787ba9af2f53c85bcd674926488b77a610e48cafbb891fced9a458f86a2ee9e1 SHA512 a7d624dad27e531cf38d73bd879e66aaf72e527d082a4adb59e259e4e5b9a779ee6938db74601fbb2be7e7b015c806109fe8dfc99d78cbd06f0ba4d8f89b28ee
+DIST rdesktop-1.9.0.tar.gz 368980 BLAKE2B c3545e1c0f8ff04adeb8f36e24684a0719a4d4bb0176491a1826b3c5c2976a96d96d773280ca5b27b936aa5f79957e7faec77be996048115d8f8c0a3f0cc0d6d SHA512 e101147b496ae70118c2756bf120007d4748aad9d9917d9ebc0878ffaf35764500861c548ef0528722777555c78e1d3d146b6f3691daa2b8657b0d3a541094f5
diff --git a/net-misc/rdesktop/rdesktop-1.9.0.ebuild b/net-misc/rdesktop/rdesktop-1.9.0.ebuild
new file mode 100644
index 000000000000..2a3e18a9ba61
--- /dev/null
+++ b/net-misc/rdesktop/rdesktop-1.9.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools eutils
+
+MY_PV=${PV/_/-}
+
+DESCRIPTION="A Remote Desktop Protocol Client"
+HOMEPAGE="http://www.rdesktop.org/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="alsa ao ipv6 kerberos oss pcsc-lite pulseaudio xrandr"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+RDEPEND="
+	dev-libs/nettle:0=
+	>=net-libs/gnutls-3.2.0:0=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	alsa? (
+		media-libs/alsa-lib
+		media-libs/libsamplerate
+	)
+	ao? (
+		>=media-libs/libao-0.8.6
+		media-libs/libsamplerate
+	)
+	kerberos? ( virtual/krb5 )
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.6.6 )
+	oss? ( media-libs/libsamplerate )
+	pulseaudio? (
+		media-libs/libsamplerate
+		media-sound/pulseaudio
+	)
+	xrandr? ( x11-libs/libXrandr )"
+DEPEND="${RDEPEND}
+	x11-libs/libXt"
+BDEPEND=virtual/pkgconfig
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.3-no_strip.patch
+	"${FILESDIR}"/${PN}-1.8.3-xrandr_configure.patch
+)
+
+DOCS=( doc/ChangeLog doc/HACKING doc/TODO doc/keymapping.txt )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	if use pulseaudio; then
+		sound_conf="--with-sound=pulse"
+	elif use ao; then
+		sound_conf="--with-sound=libao"
+	elif use alsa; then
+		sound_conf="--with-sound=alsa"
+	else
+		sound_conf=$(use_with oss sound oss)
+	fi
+
+	econf \
+		$(use_with ipv6) \
+		$(use_with xrandr) \
+		$(use_enable kerberos credssp) \
+		$(use_enable pcsc-lite smartcard) \
+		${sound_conf}
+}