From: David Seifert <soap@gentoo.org>
Date: Wed, 16 Oct 2019 11:39:51 +0000 (+0200)
Subject: media-sound/mp3c: Port to EAPI 7
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=2c1fe16a377bacfc77fedb90147a27cd2ab8060a;p=gentoo.git

media-sound/mp3c: Port to EAPI 7

Bug: https://bugs.gentoo.org/697274
Closes: https://bugs.gentoo.org/689980
Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: David Seifert <soap@gentoo.org>
---

diff --git a/media-sound/mp3c/mp3c-0.31-r1.ebuild b/media-sound/mp3c/mp3c-0.31-r1.ebuild
index 556816841642..c81de5093efc 100644
--- a/media-sound/mp3c/mp3c-0.31-r1.ebuild
+++ b/media-sound/mp3c/mp3c-0.31-r1.ebuild
@@ -1,37 +1,38 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
-inherit eutils
-
-IUSE="mp3 vorbis"
+inherit flag-o-matic toolchain-funcs
 
 DESCRIPTION="console based mp3 ripper, with cddb support"
 HOMEPAGE="http://wspse.de/WSPse/Linux-MP3c.php3"
 SRC_URI="ftp://ftp.wspse.de/pub/linux/wspse/${P}.tar.bz2"
 
-RDEPEND="mp3? ( media-sound/lame
-	>=media-sound/mp3info-0.8.4-r1 )
-	virtual/cdrtools
-	vorbis? ( media-sound/vorbis-tools )"
-
-SLOT="0"
 LICENSE="GPL-2"
+SLOT="0"
 KEYWORDS="amd64 ppc sparc x86"
+IUSE="mp3 vorbis"
 
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}/${PN}-buffer.patch"
-}
+DEPEND="sys-libs/ncurses:0="
+RDEPEND="
+	${DEPEND}
+	virtual/cdrtools
+	mp3? (
+		media-sound/lame
+		media-sound/mp3info
+	)
+	vorbis? ( media-sound/vorbis-tools )"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-buffer.patch )
 
-src_compile() {
-	econf $(use_enable vorbis oggdefaults) || die "econf failed !"
-	emake || die "emake failed!"
+src_configure() {
+	append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
+	econf $(use_enable vorbis oggdefaults)
 }
 
-src_install () {
-	make DESTDIR="${D}" install || die
-	dodoc AUTHORS *README BUGS CDDB_HOWTO ChangeLog FAQ NEWS OTHERS TODO
+src_install() {
+	default
+	dodoc BATCH.README CDDB_HOWTO OTHERS
 }