From: Thomas Beierlein <tomjbe@gentoo.org>
Date: Sat, 16 May 2020 15:05:30 +0000 (+0200)
Subject: media-radio/xastir: Minor maintennace release
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=29d557d830b4e3c08f15179d9b745afb96a62171;p=gentoo.git

media-radio/xastir: Minor maintennace release

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>
---

diff --git a/media-radio/xastir/Manifest b/media-radio/xastir/Manifest
index 48be224f00ba..db9c6180bcb1 100644
--- a/media-radio/xastir/Manifest
+++ b/media-radio/xastir/Manifest
@@ -1 +1,2 @@
 DIST xastir-2.1.4.tar.gz 2694124 BLAKE2B 90fd8ef340fc5bad43c9501c6530dcd4bd60eaab9c04638c68f80add46f0df24c45db334549915edaee95cbdcc9b7580d6343d81d84cb819f4ef5a76c9f79242 SHA512 e96f9de52499615cfe88708656d111d417e0d0e08f798b2d97f6a270db3e639c4fb5219767f8fd399fe75f51f02391ace87ae7175ae9a44cb5a4056ab7b573b1
+DIST xastir-2.1.6.tar.gz 2687180 BLAKE2B 053ee4e8d1fd589bf0767c6ffdaa7de2ef14d292d5773b2f08239fc4b73d3695e5c061dccab75caae068bc8887f7924d3793f0dfb8368b2cd25526211e240914 SHA512 91f40f3788f51589619833102d1db997ff725f84e6fa5f9b7dd8942094a1b7a94433779243be1c14b980d96613972482a397cec8e15b8ea4784fdd106c32ae08
diff --git a/media-radio/xastir/xastir-2.1.6.ebuild b/media-radio/xastir/xastir-2.1.6.ebuild
new file mode 100644
index 000000000000..344c4d649b7b
--- /dev/null
+++ b/media-radio/xastir/xastir-2.1.6.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_P=${PN/x/X}-Release-${PV}
+
+DESCRIPTION="X Amateur Station Tracking and Information Reporting"
+HOMEPAGE="http://xastir.org/"
+SRC_URI="https://github.com/Xastir/Xastir/archive/Release-${PV}.tar.gz
+			-> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="geotiff +graphicsmagick"
+
+DEPEND=">=x11-libs/motif-2.3:0
+	x11-libs/libXt
+	x11-libs/libX11
+	x11-libs/libXpm
+	x11-apps/xfontsel
+	dev-libs/libpcre
+	net-misc/curl
+	sys-libs/db:4.8
+	sci-libs/shapelib
+	!graphicsmagick? ( <media-gfx/imagemagick-7:0=[-hdri,-q32] )
+	graphicsmagick? ( media-gfx/graphicsmagick:=[-q32] )
+	geotiff? ( sci-libs/proj
+		sci-libs/libgeotiff:=
+		media-libs/tiff:0 )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	eapply_user
+
+	# fix script location (bug #407185)
+	eapply  "${FILESDIR}"/${PN}-2.1.2-scripts.diff
+
+	# do not filter duplicate flags (see bug 411095)
+	eapply -p0 "${FILESDIR}"/${PN}-2.0.0-dont-filter-flags.diff
+
+	eautoreconf
+}
+
+src_configure() {
+	# provide include path to GraphicsMagic for configure stage
+	use graphicsmagick && append-cflags -I/usr/include/GraphicsMagick
+	econf \
+		--with-shapelib \
+		--without-ax25 \
+		--without-festival \
+		--without-gpsman \
+		$(use_with !graphicsmagick imagemagick) \
+		$(use_with graphicsmagick) \
+		$(use_with geotiff libproj) \
+		$(use_with geotiff)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	rm -rf "${D}"/usr/share/doc/${PN}
+	dodoc AUTHORS ChangeLog CONTRIBUTING.md FAQ README \
+		README.Getting-Started README.MAPS README.OSM_maps
+}
+
+pkg_postinst() {
+	elog "Kernel mode AX.25 and GPSman library not supported."
+	elog
+	elog "Remember you have to be root to add addditional scripts,"
+	elog "maps and other configuration data under /usr/share/xastir."
+}