From: W. Trevor King <wking@tremily.us>
Date: Tue, 30 Sep 2014 22:10:05 +0000 (-0700)
Subject: dev-python/exam: Add this (indirect) thumbor test dependency
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=23aeabb84ab7c54b98f78b069da845fdb0217ea6;p=wtk-overlay.git

dev-python/exam: Add this (indirect) thumbor test dependency

I've submitted the find_packages sed upstream [1].

[1]: https://github.com/Fluxx/exam/pull/39
---

23aeabb84ab7c54b98f78b069da845fdb0217ea6
diff --git a/exam-9999.ebuild b/exam-9999.ebuild
new file mode 100644
index 0000000..da565e6
--- /dev/null
+++ b/exam-9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/Fluxx/${PN}.git"
+	SRC_URI=""
+else
+	SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="Helpers for better testing"
+HOMEPAGE="https://github.com/Fluxx/exam https://pypi.python.org/pypi/exam"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/mock[${PYTHON_USEDEP}]
+	"
+DEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	sed -i "s/packages=find_packages()/packages=find_packages(exclude=['tests', 'tests.*'])/" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}