From: Pacho Ramos <pacho@gentoo.org>
Date: Sat, 10 Nov 2018 12:49:34 +0000 (+0100)
Subject: media-video/motiontrack: Allow GM usage
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=21b07d746134f6a8c0ef02400df73ae77d43ec6f;p=gentoo.git

media-video/motiontrack: Allow GM usage

Closes: https://bugs.gentoo.org/314339
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
---

diff --git a/media-video/motiontrack/motiontrack-0.1.3-r2.ebuild b/media-video/motiontrack/motiontrack-0.1.3-r2.ebuild
new file mode 100644
index 000000000000..7d1989d47d41
--- /dev/null
+++ b/media-video/motiontrack/motiontrack-0.1.3-r2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic
+
+DESCRIPTION="A set of tools that detect motion between two images"
+SRC_URI="http://gemia.de/motion/${P}.tar.gz"
+HOMEPAGE="http://motiontrack.sourceforge.net"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~x86 ~ppc ~ppc64 ~sparc ~mips ~alpha ~hppa ~amd64"
+
+IUSE="debug graphicsmagick imagemagick multiprocess"
+
+RDEPEND="
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:0= )
+		graphicsmagick? ( media-gfx/graphicsmagick:0=[imagemagick] )
+	)
+	!imagemagick? ( media-libs/gd )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	# fix missing inline definition
+	# with GCC 5, bug 570352
+	append-cflags -std=gnu89
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable !imagemagick gd) \
+		$(use_enable imagemagick magick) \
+		$(use_enable multiprocess cluster)
+}
+
+src_install() {
+	default
+	dodoc src/TheCode.txt
+}