From: Virgil Dupras <vdupras@gentoo.org>
Date: Thu, 13 Sep 2018 19:41:48 +0000 (-0400)
Subject: dev-python/mysql-python: drop virtual/mysql dependency
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=1d2c680f6c4d63595d2d57fec8197d88342048d2;p=gentoo.git

dev-python/mysql-python: drop virtual/mysql dependency

Replace it with dev-db/mysql-connector-c

Closes: https://bugs.gentoo.org/665890
Package-Manager: Portage-2.3.49, Repoman-2.3.10
---

diff --git a/dev-python/mysql-python/mysql-python-1.2.5-r2.ebuild b/dev-python/mysql-python/mysql-python-1.2.5-r2.ebuild
new file mode 100644
index 000000000000..e82fab99879f
--- /dev/null
+++ b/dev-python/mysql-python/mysql-python-1.2.5-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 pypy )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN="MySQL-python"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python interface to MySQL"
+HOMEPAGE="https://sourceforge.net/projects/mysql-python/ https://pypi.org/project/MySQL-python/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+RDEPEND="dev-db/mysql-connector-c"
+DEPEND="${RDEPEND}"
+BDEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( HISTORY README.md doc/{FAQ,MySQLdb}.rst )
+
+python_configure_all() {
+	append-flags -fno-strict-aliasing
+}
+
+python_compile_all() {
+	use doc && sphinx-build -b html doc doc/_build/
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/. )
+	distutils-r1_python_install_all
+}