From: Harri Nieminen <moikkis@gmail.com>
Date: Wed, 22 Feb 2017 15:51:39 +0000 (+0200)
Subject: x11-misc/xkeycaps: EAPI bump 0 -> 6
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=19aa64095e84bffe6c51d877a7f420b9674f8aaa;p=gentoo.git

x11-misc/xkeycaps: EAPI bump 0 -> 6

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/4057
---

diff --git a/x11-misc/xkeycaps/xkeycaps-2.47-r2.ebuild b/x11-misc/xkeycaps/xkeycaps-2.47-r2.ebuild
new file mode 100644
index 000000000000..67fe8206355a
--- /dev/null
+++ b/x11-misc/xkeycaps/xkeycaps-2.47-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="GUI frontend to xmodmap"
+HOMEPAGE="http://packages.qa.debian.org/x/xkeycaps.html"
+SRC_URI="mirror://debian/pool/main/x/${PN}/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="x11-misc/xbitmaps
+	x11-libs/libX11
+	x11-libs/libXmu
+	x11-libs/libXt
+	x11-libs/libXaw
+	x11-libs/libXext"
+DEPEND="${RDEPEND}
+	x11-proto/xproto
+	x11-misc/imake
+	>=sys-apps/sed-4"
+
+DOCS=( README defining.txt hierarchy.txt sgi-microsoft.txt )
+PATCHES=(
+	"${FILESDIR}"/${P}-Imakefile.patch
+	"${FILESDIR}"/${P}-man.patch
+)
+
+src_compile() {
+	xmkmf || die
+	sed -i -e "s,all:: xkeycaps.\$(MANSUFFIX).html,all:: ,g" \
+		Makefile || die
+	emake EXTRA_LDOPTIONS="${LDFLAGS}" CC="$(tc-getCC)" \
+		CDEBUGFLAGS="${CFLAGS}"
+}
+
+src_install () {
+	default
+	newman ${PN}.man ${PN}.1
+}